Frequent access privileges error when trying to duplicate an alias file

Question

I am trying to create a set of applescripts to manage a symbolic link that points to an application's database folder. (aside: The application is not bright enough to let us select one of several databases, but a symbolic link named what the application is expecting works just fine - and was the solution suggested by the apps author.)
So I need to have a symbolic link named "app DB" in my Application Support folder. I have two symbolic links that point to the two database folders I use - one link named "app DB CD" and the other "app DB DVD" but their names don't matter. To switch which database I use with the application, I quit it, discard the "app DB" symbolic link, copy one of the other symbolic links into Application Support, change its name to "app DB" and fire up the application again. Works just fine, but I'd like to make all that an AppleScript, or at least two AppleScripts - one to swap in each database I use.
I tried to have ScriptEditor record my actions in the Finder but it did not record any of what I did except the renaming of the file. Unix's capability to copy a file and rename it at the same time would be perfect here but I don't have the Unix chops to try it yet.
I assembled a simple pair of AppleScripts that worked perfectly about a half dozen times. I was so delighted that I had gotten it to work that I just kept switching the symbolic link back & forth and launching the application for several minutes.
Sadly, like a kid playing with a toy too much it then just stopped working.
Now most of the time (but not all of the time) when the AppleScript tries to duplicate one of the symbolic links I get the following error:
"AppleScript Error
Finder got an error: The operation could not be completed because you do not have enough access privileges."
The first time I got this I checked the privileges for the files and folders. I had "read and write" for every one. On a lark I made the Group that bore my name "read and write" instead of just "read only". The AppleScript worked again - once. Then I got the same error over and over again. I went back and added "read and write" for Others (I know - not a good thing to do) and it worked again - once.
In the past day, the AppleScripts have again worked a couple of times along with 20 or 30 failures. I have not been changing the AppleScripts or the symbolic link files during this time. Through testing, it appears to throw this error at the command "duplicate" or "move":
duplicate alias file "Application Support:DB bits:app db CD"
I have found that if I try to use as a troubleshooting tool the AppleScript:
set foobar to (choose file)
and try to select the symbolic link file, it is not selectable - it is greyed out in the file list.
If I try:
set foobar to (choose folder)
I can choose the symbolic link file, but if I try to do anything with it like duplicate it, it duplicates the folder not the symbolic link file - as expected if I had thought about it.
Can anyone suggest how to reliably duplicate an alias/symbolic link file in MacOS 10.3.9? Should I instead be trying to write a Unix script and call it from AppleScript?
This is the first time in over five years that I have tried to use AppleScript, so please keep any explanations at a neophyte level. grn
G5 2x2 Mac OS X (10.3.9)

Answer 1

It's difficult to pinpoint your issue without actually seeing the code you've put together. Instead I wrote a script that sets up a situation roughly similar to yours, and then debugged that. What I found is that there are a lot of ways to do this wrong, and only one way to do it right. I could get shell scripts to work half the time, but then they stopped working altogether and I couldn't figure out why. So finally I thought it'd be best to delete the alias and tell Finder to make a fresh alias in its place as necessary.
The following demo script will work as-is with no configuration or set up. I'm hoping that you can read through the code, figure out how it works, then apply the knowledge to your script. If you need help, feel free to post your code for suggestions.
click here to open this script in your editor<pre style="font-family: 'Monaco', 'Courier New', Courier, monospace; overflow:auto; color: #222; background: #DDD; padding: 0.2em; font-size: 10px; width:400px">set test_A to "Folder A"
set test_B to "Folder B"
set the_alias to "The Alias"
set test_folder to "Alias Test Folder"
set my_desk to path to desktop folder as alias
tell application "Finder"
-- part 1: set up the test folder on the desktop
if folder test_folder of my_desk exists then
set test_folder to folder test_folder of my_desk
else -- create the folder
set test_folder to make new folder at my_desk with properties {name:test_folder}
end if
-- part 2: set up the test folders inside the test folder
if folder test_A of test_folder exists then
set folder_A to folder test_A of test_folder
set folder_B to folder test_B of test_folder
else -- create the folders
set folder_A to make new folder at test_folder with properties {name:test_A}
set folder_B to make new folder at test_folder with properties {name:test_B}
end if
-- part 3: set up the alias inside the test folder
if alias file the_alias of test_folder exists then
set the_alias to alias file the_alias of test_folder
else -- create the alias
set the_alias to make new alias file at test_folder to folder_A with properties {name:"The Alias"}
end if
-- part 4: choose where to link The Alias
set linked to ""
repeat
set msg to "Select a new destination for The Alias:"
if linked is not "" then set msg to "The Alias now links to " & linked & return & return & msg
tell me to set toggle to button returned of (display dialog msg buttons {"Quit", "Folder A", "Folder B"})
if toggle is "Folder A" then
set linked to test_A
delete the_alias
set the_alias to make new alias file at test_folder to folder_A with properties {name:"The Alias"}
else if toggle is "Folder B" then
set linked to test_B
delete the_alias
set the_alias to make new alias file at test_folder to folder_B with properties {name:"The Alias"}
else if toggle is "Quit" then
exit repeat
end if
end repeat
end tell
</pre>