FRM-41214 when specifying reports server

Question

Hi all,
we use forms/reports 11g
we call our reports from forms
as soon as we include this in our code :
SET_REPORT_OBJECT_PROPERTY(rp2rroNodeId,REPORT_SERVER,rp2rroReportServer);or fill out the property Report Server of the reports object in forms builder
this causes FRM-41214 when calling
rp2rro_jobidFull:=run_report_object(rp2rroNodeId);however when we look in the reports queue the report is run without a problem
which prooves that we specified the correct reports server
report destination type is CACHE
nothing shows up in the reports logfiles
any solution/cause
Kr
Martin

Answer 1

In order to rule out code or configuration, I would recommend trying some simpler code and not use rp2rro library.
Here is some simplified code which is based on the example document Oracle has provided for a long time. To use it do the following:
1. In your form, create a dummy report object named REPORT1. Don't worry about its properties as these will be set in code.
2. In the code below, replace :block1.SERVERNAME with the name of your Reports Server. You can hard code it or use a variable. This value appears a couple of times in the code so be careful.
3. In the code below, replace :block1.REPNAME with the path and name of the Reports rdf file you plan to use for your report.
4. If you are not using the HTTP Server and are calling WLS directly, you will need to change the relative URL in the Web.Show call to a fully qualified URL and ensure the correct port is indicated. This will not be necessary if requests are being routed through HTTP Server.
5. Put this code in a test button and run the form.
Declare
     repid           REPORT_OBJECT;
     v_rep           varchar2(256);
     rep_status           varchar2(256);
Begin
       repid := find_report_object('REPORT1');
-- Set Report Object properties
          SET_REPORT_OBJECT_PROPERTY(repid, REPORT_DESTYPE, CACHE);
          SET_REPORT_OBJECT_PROPERTY(repid, REPORT_DESFORMAT, 'HTML');
          -- Comm mode 1 = SYNCHRONOUS
          -- Comm mode 2 = ASYNCHRONOUS
          SET_REPORT_OBJECT_PROPERTY(repid, REPORT_COMM_MODE, 1);
          SET_REPORT_OBJECT_PROPERTY(repid, REPORT_SERVER, :block1.SERVERNAME);           
          SET_REPORT_OBJECT_PROPERTY(repid, REPORT_FILENAME, :block1.REPNAME);
          -- SET_REPORT_OBJECT_PROPERTY(repid,REPORT_OTHER,:block1.otherparams);
          SYNCHRONIZE;
-- Run report and get status
          v_rep      := RUN_REPORT_OBJECT(repid);
          rep_status      := report_object_status(v_rep);
          SYNCHRONIZE;
-- Wait for Reports to generate results
    WHILE rep_status in ('RUNNING','OPENING_REPORT','ENQUEUED')
    LOOP
          rep_status := report_object_status(v_rep);
    END LOOP;
    SYNCHRONIZE;
-- If DESTYPE is appropriate for displaying to user, execute WEB.SHOW   
    IF rep_status = 'FINISHED' THEN          
      WEB.SHOW_DOCUMENT('/reports/rwservlet/getjobid'||substr(v_rep,instr(v_rep,'_',-1)+1)||'?'||'server='||:block1.SERVERNAME,'_blank');     
    ELSE
      message(rep_status);
    END IF; 
END;If the above works correctly, you can probably assume your issue is in your code. However if it fails in the same manner as you saw previously, the issue is likely related to a config problem. You may need to use the Reports Naming Service. Refer to the following:
http://docs.oracle.com/cd/E21764_01/bi.1111/b32121/pbr_arch003.htm#CHDHBFFC