Handling errors inside Procedure

Question

Hi..
I have created the following procedure.. and the procedure work out well when there are no duplicates in the table.
If the duplicate arises the errors messages is also displayed..
CREATE OR REPLACE PROCEDURE P_MC_IPS (lDate IN
DATE) IS
PROJ_INV VARCHAR2(50);
MAC_IP VARCHAR2(100);
CURSOR M_IP IS
SELECT DISTINCT A.TITLE TITLE,B.MACHINE_IP MACHINE_IP FROM JOB_LIST A,TD B WHERE A.JOBNUMBER = B.JOBNO AND B.ACT_DATE = TO_CHAR(ldate,'DD-MON-YYYY');
BEGIN
OPEN M_IP;
LOOP
FETCH M_IP INTO PROJ_INV,MAC_IP;
EXIT WHEN M_IP%NOTFOUND;
INSERT INTO NET_ADDRESS(P_INV,MACHINE_IPS) VALUES(PROJ_INV,MAC_IP);
COMMIT;
END LOOP;
CLOSE M_IP;
EXCEPTION
WHEN DUP_VAL_ON_INDEX THEN
DBMS_OUTPUT.PUT_LINE('DUPLICATE RECORDS EXISTS');
END P_MC_IPS;
The Problem here is I need to insert other values except the datas that has duplicate index.
I need to insert the data except the duplicate record when i run the procedure again.
I need to use the exception type "UP_VAL_ON_INDEX " to handle the exception. Can anyone help out regd. this
Kindly help me on this issue.
Thanks
gayathri

Answer 1

Use an inner block to handle the exception.
CREATE OR REPLACE PROCEDURE p_mc_ips
   (lDate IN DATE)
IS
BEGIN
   FOR lrec IN (SELECT DISTINCT a.title title,b.machine_ip machine_ip
                FROM job_list a,td b
                WHERE a.jobnumber = b.jobno
                AND b.act_date = TO_CHAR(ldate,'DD-MON-YYYY'))
   LOOP
      BEGIN
         INSERT INTO net_address(p_inv,machine_ips)
         VALUES(lrec.title, lrec.machine_ip);
      EXCEPTION
         WHEN DUP_VAL_ON_INDEX THEN
            DBMS_OUTPUT.PUT_LINE('DUPLICATE RECORDS EXISTS');
      END;
   END LOOP;
   COMMIT;
END p_mc_ips;You'll have noticed that I've streamlined your code a bit. We'll save using FORALL and anti-joins for another day ;)
Cheers, APC