Hash created using DBMS_CRYPTO.Hash and md5sum, sha1sum not maching.

Question

Hi,
I have PL/SQL script MD5SH1.sql to generate md5 and sha1 hash, but hash generated by this script and
hash generated by md5sum and sha1sum utility not matching.
Pl. tell me what is wrong,
------------------MD5SH1.sql----------------
set serveroutput on
DECLARE
input_string VARCHAR2 (200) := 'Lord of the ring'';
output_str_md5 VARCHAR2 (200);
output_str_sh1 VARCHAR2 (200);
hash_raw_md5 RAW(2000);
hash_raw_sh1 RAW(2000);
hash_algo_type1 PLS_INTEGER := DBMS_CRYPTO.HASH_MD5;
hash_algo_type2 PLS_INTEGER := DBMS_CRYPTO.HASH_SH1;
BEGIN
DBMS_OUTPUT.PUT_LINE ( 'Original string: ' || input_string);
hash_raw_md5 := DBMS_CRYPTO.Hash
src => UTL_I18N.STRING_TO_RAW (input_string, NULL),
--src => input_string,
typ => hash_algo_type1
hash_raw_sh1 := DBMS_CRYPTO.Hash
src => UTL_I18N.STRING_TO_RAW (input_string, NULL),
--src => input_string,
typ => hash_algo_type2
output_str_md5 := UTL_I18N.RAW_TO_CHAR (hash_raw_md5,'US7ASCII');
output_str_sh1 := UTL_I18N.RAW_TO_CHAR (hash_raw_sh1,'US7ASCII');
--output_str_md5 := hash_raw_md5;
--output_str_sh1 := hash_raw_sh1;
--dbms_output.put_line(hash_raw_md5);
--dbms_output.put_line(rawtohex(hash_raw_sh1));
DBMS_OUTPUT.PUT_LINE ('MD5 Hash: ' || output_str_md5);
DBMS_OUTPUT.PUT_LINE ('SH1 Hash: ' || output_str_sh1);
END;
~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
The O/p of this script is
SYS@mydb> @MD5SH1.sql
Original string: Lord of the ring
MD5 Hash: �����+.v�`�a_A
SH1 Hash:
����E�k�[�F[c�2�
PL/SQL procedure successfully completed.
SYS@mydb>
~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
The o/p of md5sum and sha1sum is
~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
[san@sde4 ~]$ echo "Lord of the ring" |md5sum
f3fbb6dfd8a2d6f8f6aeabc4d6e17c57 -
[san@sde4 ~]$ echo "Lord of the ring" |sha1sum
856f6132e23c7e335ca4188bd45c7bc9515f6905 -
[san@sde4 ~]$
~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
Why these 2 hashes are not matching?
-Santosh Mhaskar

Answer 1

You should take in account, that echo command adds a carriage return by default.
SQL> set serveroutput on
SQL> set echo on
SQL> declare
  2    input_string       varchar2(200) := 'Lord of the ring'||chr(10);
  3    output_str_md5  varchar2(200);
  4    output_str_sh1  varchar2(200);
  5    hash_raw_md5       raw(2000);
  6    hash_raw_sh1       raw(2000);
  7    hash_algo_type1 pls_integer := dbms_crypto.hash_md5;
  8    hash_algo_type2 pls_integer := dbms_crypto.hash_sh1;
  9
10  begin
11    dbms_output.put_line('Original string: ' || input_string);
12    hash_raw_md5      := dbms_crypto.hash(src => utl_raw.cast_to_raw(input_string),
13                                       typ => hash_algo_type1);
14    hash_raw_sh1      := dbms_crypto.hash(src => utl_raw.cast_to_raw(input_string),
15                                       typ => hash_algo_type2);
16    dbms_output.put_line('MD5 Hash: ' || lower(rawtohex(hash_raw_md5)));
17    dbms_output.put_line('SH1 Hash: ' || lower(rawtohex(hash_raw_sh1)));
18  end;
19  /
Original string: Lord of the ring
MD5 Hash: f3fbb6dfd8a2d6f8f6aeabc4d6e17c57
SH1 Hash: 856f6132e23c7e335ca4188bd45c7bc9515f6905
PL/SQL procedure successfully completed.
SQL> !echo "MD5 Hash:" `echo 'Lord of the ring' | md5sum`
MD5 Hash: f3fbb6dfd8a2d6f8f6aeabc4d6e17c57 -
SQL> !echo "SH1 Hash:" `echo 'Lord of the ring' | sha1sum`
SH1 Hash: 856f6132e23c7e335ca4188bd45c7bc9515f6905 -Best regards
Maxim