Having an AppleScript Move All Files of a Certain Type From Sub-Folders to Trash

Question

Greetings, everyone. With my introductory post, I would like to ask for help with an AppleScript I've been slaving over for the past five hours or so. I have tried Terminal and Finder commands both, along with lots and lots of Googling, and I cannot seem to get this to work.
Specfically, I want a script to look into a folder and all of its sub-directories, locate all files with a certain extension (in this case, APP), and then send every one of those files to the trash. Originally, I planned to delete them directly with Terminal commands that required verification, but I couldn't get that to work, and I thought that this would be a more average user-friendly version, anyway.
I also wondered if there was any universal means of referring to a system drive without referring to it by its name, since (as you'll see in the script) the directory that these *.app files will be moved from is in the Users/Shared hierarchy. However, it's meant to be used on multiple computers, so naming the OS drive on one won't work for others. If no such wild card exists, is what I'm doing now (having the script placed in the root folder of the OS drive) acceptable?
As it is, when I run this script, it displays all the dialogs, but the APP files aren't moved. It doesn't error at all in the AppleScript editor, it just runs and then closes down. I don't know what I'm doing wrong.
Thank you in advance for any help you can provide.
=====
if button returned of (display dialog "Trash all of the APP files in your SuchAndSuch folder? (This script must be in the root directory of your system drive.)" buttons {"Yes, I'm ready", "No"} default button 2 cancel button 2 with title "SuchAndSuch Folder Prep" with icon caution) is "Yes, I'm ready" then
    set theFolder to ":Users:Shared:SuchAndSuch:" as alias
    tell application "Finder"
        set theFiles to every file of theFolder whose name extension is "app"
        move theFiles to trash
    end tell
end if
if button returned of (display dialog "The APP files have been trashed." buttons {"OK"} default button 1 with title "SuchAndSuch Folder Prep" with icon 1) is "OK" then
end if

Answer 1

Well, you've done more fiddling than that; you've moved everything inside the Finder tell block.  Why did you do that?  If you recall my point 2 above, it is difficult to use POSIX paths or the POSIX file command inside Finder tell blocks without generating errors, but you've done both in your revision.  I'm surprised that you're surprised that it doesn't work. 
Applescript tries to be user-friendly, but it's still a programming language, and like any programming language the devil is in the details.  Changes that seem small and innocuous to you can make big differences in the result you get.
Now:
/Users/Shared should be machine independent in POSIX: you don't need to specify the hard drive name and it should be universal on all OS X installations.  You can specify it directly.
The Finder's delete command moves fils to the trash, it doesn't erase them.  Trying to use the move command to get files to the trash is a little bass-ackwards.
Don't put anything inside a Finder tell block unless it has to be processed by the Finder.  If you do you're just begging for errors.
There's no need to put the script at the root level of the drive.  If the Finder needs permission to delete a file it will ask.
untangled and revised:
set subfolderOfSharedFolder to quoted form of "/Users/Shared/<subfolder name>"
set response to display dialog "Trash all of the APP files in your <subfolder name> folder?" buttons {"Yes, I'm ready", "No"} default button 2 cancel button 2 with title "<subfolder name> Folder Prep" with icon caution
if button returned of response is "Yes, I'm ready" then
  -- run spotlight search
          set filesToDelete to paragraphs of (do shell script "mdfind 'kMDItemFSName == *.app c' -onlyin " & subfolderOfSharedFolder)
  -- convert posix paths to file specifiers
          repeat with thisFile in filesToDelete
                    set (contents of thisFile) to POSIX file thisFile
          end repeat
          tell application "Finder"
  delete filesToDelete
          end tell
          if button returned of (display dialog "The APP files have been trashed." buttons {"OK"} default button 1 with title "SuchAndSuch Folder Prep" with icon 1) is "OK" then
          end if
end if