Help on ALV with multiple header/item output

Question

Dear all:
Below is the actual working code on a multiple header/item display. The alv is supposed to output the details differently in each list. But somehow it only display the last i_tab I gave in all the list(they all look the same). Please help me out here how I can change my code to work properly. Thanks...
*& Report  ZTEST2
REPORT  ZTEST2.
type-pools: slis.
data : NUM1 type I,
       NUM type I,
       begin of str,
       client like mara-mandt,
       mat like mara-matnr,
       end of str,
       tab like standard table of str.
data :wa2 type slis_alv_event ,
      tab2 like standard table of wa2,
      wa1 type   slis_layout_alv,
      wa type line of slis_t_fieldcat_alv,
       tab1 like standard table of wa.
       wa-reptext_ddic = 'Client Num'.
       wa-fieldname = 'CLIENT'.
       wa-tabname = 'TAB'.
       wa-ref_fieldname = 'MANDT'.
       wa-ref_tabname = 'MARA'.
       wa-seltext_l = 'CLIENT'.
       append wa to tab1.
       wa-reptext_ddic = 'Mat Number'.
       wa-fieldname = 'MAT'.
       wa-tabname = 'TAB'.
       wa-ref_fieldname = 'MATNR'.
       wa-ref_tabname = 'MARA'.
       wa-seltext_l = 'MATERIAL'.
       append wa to tab1.
      wa1-no_colhead = 'X'.
       wa2-NAME = SLIS_EV_TOP_OF_PAGE.
       wa2-FORM = 'WRITE_TOP_PAGE'.
       APPEND wa2 TO tab2.
NUM = 0.
CALL FUNCTION 'REUSE_ALV_BLOCK_LIST_INIT'
  EXPORTING
    I_CALLBACK_PROGRAM             = sy-cprog.
do 2 times.
NUM1 = NUM1 + 10.
refresh: tab.
select mandt matnr up to NUM1 rows from mara into table tab.
CALL FUNCTION 'REUSE_ALV_BLOCK_LIST_APPEND'
  EXPORTING
    IS_LAYOUT                        = wa1
    IT_FIELDCAT                      = tab1
    I_TABNAME                        = 'TAB'
    IT_EVENTS                        = tab2
  TABLES
    T_OUTTAB                         = tab.
enddo.
CALL FUNCTION 'REUSE_ALV_BLOCK_LIST_DISPLAY'.
FORM WRITE_TOP_PAGE.
  NUM = NUM + 1.
  WRITE: / ,
         / 'TABLE NUMBER :', NUM.
ENDFORM.

Answer 1

Hi Jim,
yes for some reason ALV expects you to be using different tables. It seems that it does not save the contents of the tables at each call of 'append' rather it waits until 'display' to deal with the table contents at that time, which in your case is the 20 items.
What you can do is use dynamic tables. check this out:
REPORT  ZNRW_ALV_BLOCK                          .
type-pools: slis.
data : NUM1 type I,
NUM type I.
types:
begin of str,
client like mara-mandt,
mat like mara-matnr,
end of str.
data
tab type standard table of str.
data :wa2 type slis_alv_event ,
tab2 like standard table of wa2,
wa1 type slis_layout_alv,
wa type line of slis_t_fieldcat_alv,
tab1 like standard table of wa.
wa-reptext_ddic = 'Client Num'.
wa-fieldname = 'CLIENT'.
wa-tabname = 'TAB'.
wa-ref_fieldname = 'MANDT'.
wa-ref_tabname = 'MARA'.
wa-seltext_l = 'CLIENT'.
append wa to tab1.
wa-reptext_ddic = 'Mat Number'.
wa-fieldname = 'MAT'.
wa-tabname = 'TAB'.
wa-ref_fieldname = 'MATNR'.
wa-ref_tabname = 'MARA'.
wa-seltext_l = 'MATERIAL'.
append wa to tab1.
wa1-no_colhead = 'X'.
wa2-NAME = SLIS_EV_TOP_OF_PAGE.
wa2-FORM = 'WRITE_TOP_PAGE'.
APPEND wa2 TO tab2.
NUM = 0.
CALL FUNCTION 'REUSE_ALV_BLOCK_LIST_INIT'
EXPORTING
I_CALLBACK_PROGRAM = sy-cprog.
DATA tabDREF TYPE REF TO DATA.
FIELD-SYMBOLS <tab> TYPE table.
do 2 times.
CREATE DATA tabdref TYPE table of str.
ASSIGN tabDREF->* TO <tab>.
NUM1 = NUM1 + 10.
refresh: tab.
select mandt matnr up to NUM1 rows from mara into table <tab>.
CALL FUNCTION 'REUSE_ALV_BLOCK_LIST_APPEND'
EXPORTING
IS_LAYOUT = wa1
IT_FIELDCAT = tab1
I_TABNAME = 'TAB'
IT_EVENTS = tab2
TABLES
T_OUTTAB = <tab>.
enddo.
CALL FUNCTION 'REUSE_ALV_BLOCK_LIST_DISPLAY'.
FORM WRITE_TOP_PAGE.
NUM = NUM + 1.
WRITE: / ,
/ 'TABLE NUMBER :', NUM.
ENDFORM.