Help on autonomous transaction

Question

Hi All.
I've been testing the use of AT and have come to the following doubt:
The example below is based on the Summit Schema:
1) Log table to insert audit info:
create table traza_error
(co_error integer not null
,tx_error varchar2(4000) not null
,fe_error date not null
,usuario_error varchar2(30)
,equipo_error varchar2(200))
2) Procedure to insert info on log table:
create or replace procedure registra_log_error is
pragma autonomous_transaction;
r_traza traza_error % rowtype;
begin
r_traza.co_error := sqlcode;
r_traza.tx_error := substr(sqlerrm,1,4000);
r_traza.fe_error := sysdate;
r_traza.usuario_error := user;
r_traza.equipo_error := sys_context('userenv','terminal');
insert
into traza_error
values r_traza;
commit;
end;
3) Procedure to insert rows on S_EMP table:
create or replace procedure registra_empleado (r_emp in s_emp % rowtype) is
begin
insert
into s_emp
values r_emp;
end registra_empleado;
4) Anonymous block to insert rows on S_EMP table and raise error:
declare
r_emp s_emp % rowtype;
begin
r_emp.id := 98;
r_emp.last_name := 'Perez';
r_emp.first_name := 'Pedro';
r_emp.dept_id := 34;
registra_empleado (r_emp);
r_emp.id := 99;
r_emp.last_name := 'Perez';
r_emp.first_name := 'Pablo';
r_emp.dept_id := 111;
registra_empleado (r_emp);
commit;
dbms_output.put_line('Registrado el empleado: '||r_emp.first_name||','||r_emp.last_name);
exception
when others then
dbms_output.put_line('Ocurrió el error '||sqlcode||' se registrará en la auditoria de Log');
registra_log_error;
end;
5) Comments:
Anonymous block must inserts two records, the first one succeeds, second must fail as dept_id 111 is not a valid id (fk with s_dept).
My point is that, as i understand, the main block (anonymous) must fail an insert no records. However when autonomous transaction is called(registra_log_error) the commit in it , commit boths, the log error record and also the first insert on the S_EMP table.
From my understanding of AT, the pragma starts a new transaction. For me, that implies another logical unit of work, and as though it should only commit the log record, not boths.
The whole idea of the log error routine is to be independent of the main transaction, as would happen on a real world situation.
Please, anyone, clarify on this one ....
Help will be greatly appreciated ....!

Answer 1

Your understanding of how autonomous transactions should work is correct - the work of the autonomous transaction is committed independently of the main transaction.
From a quick look at your example, this has nothing to do with the autonomous transaction nor its commit boundaries but everything to do with having an exception handler that does not raise or rollback and the difference in this regard between handled and unhandled exceptions.
See the difference between this:
SQL> create table t1
  2  (col1 number primary key);
Table created.
SQL> begin
  2   insert into t1 values (1);
  3   insert into t1 values (1);
  4  exception when dup_val_on_index then null;
  5  end;
  6  /
PL/SQL procedure successfully completed.
SQL> select * from t1;
      COL1
         1
SQL> rollback;
Rollback complete.
SQL> select * from t1;
no rows selectedand this:
SQL>  begin
  2    insert into t1 values (1);
  3    insert into t1 values (1);
  4   end;
  5  /
begin
ERROR at line 1:
ORA-00001: unique constraint (RIMS.SYS_C00167927) violated
ORA-06512: at line 3
SQL> select * from t1;
no rows selected
SQL> or this:
SQL> begin
  2   insert into t1 values (1);
  3   insert into t1 values (1);
  4  exception when dup_val_on_index then
  5   -- do some stuff then
  6   raise;
  7  end;
  8  /
begin
ERROR at line 1:
ORA-00001: unique constraint (RIMS.SYS_C00167927) violated
ORA-06512: at line 6
SQL>  select * from t1;
no rows selected
SQL>