Help with Create Folders and Sort Applescript

Question

Hi guys! I'm sure this is an easy fix but I can't seem to find the right things to add to to this script. I am using a script that Jacques Rioux kindly helped me out with a couple days ago. I altered his script a little to complete a different task I needed to create a shortcut for. The script below first creates two folders (TIFF & JPEG) and then it sorts files with an extension .tif into the 'TIFF' folder and files with the extension .jpg into the folder named 'JPEG'. This works great but I would like the script to effect multiple folders. Can anyone help me add to the script so when you click it, a prompt will pop up allowing you to choose multiple folders to apply the script too? As of now it will only work on one folder at a time. I would greatly greatly apprecaite the help. Thanks!!
try
          tell application "Finder" to set targetFolder to (target of the front Finder window) as string
on error -- no window
end try
do shell script "cd " & (quoted form of POSIX path of targetFolder) & "; mkdir -p TIFF/ JPEG/"
tell application "Finder"
          move (every file of folder targetFolder whose name extension is in {"tif"}) to folder "TIFF" of folder targetFolder
          move (every file of folder targetFolder whose name extension is "jpg") to folder "JPEG" of folder targetFolder
end tell
Best,
Anthony

Answer 1

All you need to do is choose multiple folders (instead of just getting the target of the front Finder window), then repeat through the list of chosen folders, for example:
set targetFolders to (choose folder with multiple selections allowed)
repeat with aFolder in targetFolders
   do shell script "cd " & (quoted form of POSIX path of aFolder) & "; mkdir -p TIFF/ JPEG/"
   tell application "Finder"
      move (every file of aFolder whose name extension is in {"tif"}) to folder "TIFF" of aFolder
      move (every file of aFolder whose name extension is "jpg") to folder "JPEG" of aFolder
   end tell
end repeat