Help with parsing a text string in address book and moving it to 'related person' field

Question

I am wanting to make a little applescript that will go thru my contacts and find data in the NOTES field and parse it slightly and move it to another field.  (sorry if parsing isn't the right word here)
The data to be found is a GPS coordinate with this EXACT format:
<Lat:12.345678><Lon:-12.345678>
...the only thing different from this example is the digits, and the number of digits.
What I want to end up doing is deleting this data from the NOTES field, but leaving any other data, (this part sounds difficult to do to, to me!)
And moving it to a related person field with the label gps, and the coordinate now reading exactly:
12.345678,-12.345678
(FYI, you can copy/paste a coordinate like this very fast into the maps app on iPhone and locate it instantly)
Thanks for the help on this
If this is too complicated I can break up the process into steps.  I know how to do some of it, but not sure about the parsing, and then delete just part of the notes field...
Thanks!

Answer 1

Hi,
This script work here, try it :
tell application "Address Book"
    repeat with thisContact in (get people)
        set tNote to note of thisContact
        if tNote is not missing value and "<Lat:" is in tNote and "<Lon:" is in tNote then
            set {GPS_value, newNote} to my getGPS_coordinate(tNote)
            if newNote is not "" then -- no error
                set gpsField to (related names of thisContact whose its label = "gps")
                if gpsField is not {} then
                    set value of (item 1 of gpsField) to GPS_value
                else -- field "gps" is empty
                    make new related name at end of related names of thisContact with properties {label:"gps", value:GPS_value}
                end if
                set note of thisContact to newNote
            end if
        end if
    end repeat
    save
end tell
on getGPS_coordinate(this_note)
    set oldTid to text item delimiters
    set {tLat, tLon, newNote} to {"", "", ""}
    try
        set text item delimiters to "<Lat:"
        set tLat to text item 2 of this_note
        set text item delimiters to "<Lon:"
        set tLon to text item 2 of this_note
        set text item delimiters to ">"
        set {tLat, tLon} to {text item 1 of tLat, text item 1 of tLon} -- get values (lat... and long...)
        set text item delimiters to "<Lat:" & tLat & "><Lon:" & tLon & ">"
        set this_note to text items of this_note
        set text item delimiters to " "
        set newNote to this_note as string -- delete GPS coordinate in this note
    end try
    set text item delimiters to oldTid
    return {tLat & "," & tLon, newNote}
end getGPS_coordinate