Highlight and speak a line of text

Question

I am trying to create a single key shortcut to highlight a line of text, or sentence in Word then have the computer speak it. My brother is non-verbal and has limited control over his body. He uses a large keyboard device to speak, but would rather use his mac laptop. He can't manipulate the mouse very well, and can only hit one key at a time. So there are a lot of constraints. I would like to create a shortcut so that once he types out a sentence he can then hit a single key and it will speak the sentence out loud. I have figured out some small parts of this, but nothing that ties it all together. It looks like Applescript might be my only hope, but I can't write script for crap. Any help or tips would be greatly appreciated.

Answer 1

Here's a script that I just wrote real quick that may or may not work exactly as you need...
<pre style="width:630px;height:auto;overflow-x:auto;overflow-y:hidden;"
title="Copy this code and paste it into your Script Editor application.">property bQuit : "Quit"
property bIdle : "Idle"
property bSpeak : "Speak"
global what2Say
on run
set what2Say to "I have something to say..."
speakit()
end run
on reopen
speakit()
end reopen
on speakit()
repeat
display dialog "Enter text to be spoken:" default answer what2Say buttons ¬
{bQuit, bIdle, bSpeak} default button 3 giving up after 99999999
set {bChoice, what2Say, gaveUp} to ¬
{button returned of result, text returned of result, gave up of result}
if bChoice is bSpeak then
say what2Say
else if bChoice is bIdle or gaveUp then
exit repeat
else if bChoice is bQuit then
quit
return
end if
end repeat
end speakit
on quit
continue quit
end quit</pre>
Save the above script as an Application and make sure it's set to "Stay Open". Once saved, when the script is launched it will display a dialog that you can type something into. You have 3 button choices. If you click "Speak" (this button can be clicked by simply pressing the return key) it will say what was typed in the text box and then display another dialog to type in. If you click "Idle" the script will stay launched, but wait until you click on its icon in the Dock before displaying another dialog. If you click "Quit", well... the script will quit.
You can also design a super simple Automator Service that will do almost the same exact thing, but I can't figure out how to assign only one key to make it active (2 keys is simple, but you say he's limited to just 1).
Hope this helps or at least gives you some other options!