How can I select 2 options in Interactive reports

Question

Hi Friends
I have a doubt about Interactive reports/ ALV interactive reports. Is there any option to select multiple selections in interactive reports. If I am displaying in a screen CustNo, Name, Country.
I want to see order details of that customer in another screen using AT Line-Selection. Can I select multiple customer nos at a time and also can I see those order details whom I selected over in first list.
Please send me reply ASAP if there is any option with suitable example.
Thanks
Praveen.

Answer 1

Check out this sample.  It uses two ALV grids.  On the first one you can do multiple selection, hit the continue buttons and it will throw another ALV with those material/plant records.  Implement the following program.  Create screen 100 and 200.  One each screen create a custom container called ALV_CONTAINER(screen 100) and ALV_CONTAINER2(screen 200).  Create the gui status for both.  Don't forget to create a "CONTINUE" button on the gui-status 100.
report zrich_0006.
tables: mara.
type-pools: slis, icon.
* Internal Tables
data: begin of ialv occurs 0,
      matnr type mara-matnr,
      maktx type makt-maktx,
      end of ialv .
data: begin of ialv2 occurs 0,
      matnr type mara-matnr,
      werks type marc-werks,
      end of ialv2.
* Miscellanous Variables
data: index_rows type lvc_t_row,
      index like line of index_rows.
data: alv_container type ref to cl_gui_custom_container,
      alv_container2 type ref to cl_gui_custom_container,
      alv_grid type ref to cl_gui_alv_grid,
      alv_grid2 type ref to cl_gui_alv_grid,
      row_table type lvc_t_row with header line,
      ok_code like sy-ucomm,
      layout  type lvc_s_layo,
      fieldcat type lvc_t_fcat,
      fieldcat2 type lvc_t_fcat.
select-options: s_matnr for mara-matnr.
start-of-selection.
  select mara~matnr makt~maktx
             into corresponding fields of table ialv
                 from mara
                      inner join makt
                         on mara~matnr = makt~matnr
                                where mara~matnr in s_matnr
                                  and makt~spras = sy-langu.
  sort ialv ascending by matnr.
  call screen 100.
*      Module  status_0100  OUTPUT
module status_0100 output.
  set pf-status '0100'.
  set titlebar '0100'.
  data: lt_exclude type ui_functions.
* Create Controls
  create object alv_container
         exporting container_name = 'ALV_CONTAINER'.
  create object alv_grid
         exporting  i_parent =  alv_container.
*  Populate Field Catalog
  perform get_fieldcatalog.
* Optionally restrict generic functions to 'change only'.
* (The user shall not be able to add new lines).
  perform exclude_tb_functions changing lt_exclude.
* Set selection mode to "D"  --  Multiple Lines
  layout-sel_mode = 'D'.
  call method alv_grid->set_table_for_first_display
      exporting
           is_layout              = layout
           it_toolbar_excluding   = lt_exclude
           i_structure_name       = 'IALV'
      changing
           it_outtab       = ialv[]
           it_fieldcatalog = fieldcat[].
endmodule.
*      Module  USER_COMMAND_0100  INPUT
module user_command_0100 input.
  case sy-ucomm.
    when 'BACK' or 'CANC'.
      perform free_containers.
      if sy-subrc = 0.
        set screen 0.
        leave screen.
      else.
        leave program.
      endif.
    when 'EXIT'.
      perform free_containers.
      leave program.
    when 'CONTINUE'.
* Retrieve selected rows from ALV grid
  clear index_rows.  refresh index_rows.
  call method alv_grid->get_selected_rows
           importing
                 et_index_rows = index_rows.
* Do something with those selected rows here
      loop at index_rows into index.
        read table ialv index index-index.
        if sy-subrc = 0.
          select * appending corresponding fields of table ialv2
                       from marc
                           where matnr = ialv-matnr.
        endif.
      endloop.
      perform free_containers.
      leave to screen 200.
  endcase.
endmodule.
*      Form  FREE_CONTAINERS
form free_containers.
  if not alv_container is initial.
    call method alv_container->free.
    clear: alv_container.
    free : alv_container.
  endif.
  if not alv_container2 is initial.
    call method alv_container2->free.
    clear: alv_container2.
    free : alv_container2.
  endif.
endform.
*      Form  Get_Fieldcatalog - Set Up Columns/Headers
form get_fieldcatalog.
  data: ls_fcat type lvc_s_fcat.
  data: columnno(3) type n value '0'.
  refresh: fieldcat.
  clear: ls_fcat.
  ls_fcat-reptext    = 'Material Number'.
  ls_fcat-coltext    = 'Material Number'.
  ls_fcat-fieldname  = 'MATNR'.
  ls_fcat-ref_table  = 'IALV'.
  ls_fcat-outputlen  = '18'.
  ls_fcat-col_pos    = 1.
  append ls_fcat to fieldcat.
  clear: ls_fcat.
  ls_fcat-reptext    = 'Material Description'.
  ls_fcat-coltext    = 'Material Description'.
  ls_fcat-fieldname  = 'MATKX'.
  ls_fcat-ref_table  = 'IALV'.
  ls_fcat-outputlen  = '40'.
  ls_fcat-col_pos    = 2.
  append ls_fcat to fieldcat.
endform.
*      Form  Get_Fieldcatalog2 - Set Up Columns/Headers
form get_fieldcatalog2.
  data: ls_fcat type lvc_s_fcat.
  data: columnno(3) type n value '0'.
  refresh: fieldcat2.
  clear: ls_fcat.
  ls_fcat-reptext    = 'Material Number'.
  ls_fcat-coltext    = 'Material Number'.
  ls_fcat-fieldname  = 'MATNR'.
  ls_fcat-ref_table  = 'IALV2'.
  ls_fcat-outputlen  = '18'.
  ls_fcat-col_pos    = 1.
  append ls_fcat to fieldcat2.
  clear: ls_fcat.
  ls_fcat-reptext    = 'Plant'.
  ls_fcat-coltext    = 'Plant'.
  ls_fcat-fieldname  = 'WERKS'.
  ls_fcat-ref_table  = 'IALV2'.
  ls_fcat-outputlen  = '4'.
  ls_fcat-col_pos    = 2.
  append ls_fcat to fieldcat2.
endform.
*      Form  EXCLUDE_TB_FUNCTIONS
form exclude_tb_functions changing pt_exclude type ui_functions.
* Only allow to change data not to create new entries (exclude
* generic functions).
  data ls_exclude type ui_func.
  ls_exclude = cl_gui_alv_grid=>mc_fc_loc_copy_row.
  append ls_exclude to pt_exclude.
  ls_exclude = cl_gui_alv_grid=>mc_fc_loc_delete_row.
  append ls_exclude to pt_exclude.
  ls_exclude = cl_gui_alv_grid=>mc_fc_loc_append_row.
  append ls_exclude to pt_exclude.
  ls_exclude = cl_gui_alv_grid=>mc_fc_loc_insert_row.
  append ls_exclude to pt_exclude.
  ls_exclude = cl_gui_alv_grid=>mc_fc_loc_move_row.
  append ls_exclude to pt_exclude.
endform.
*      Module  status_0200  OUTPUT
module status_0200 output.
  set pf-status '0200'.
  set titlebar '0200'.
* Create Controls
  create object alv_container2
         exporting container_name = 'ALV_CONTAINER2'.
  create object alv_grid2
         exporting  i_parent =  alv_container2.
*  Populate Field Catalog
  perform get_fieldcatalog2.
  call method alv_grid2->set_table_for_first_display
      changing
           it_outtab       = ialv2[]
           it_fieldcatalog = fieldcat2[].
endmodule.
*      Module  USER_COMMAND_0200  INPUT
module user_command_0200 input.
  case sy-ucomm.
    when 'BACK' or 'CANC'.
      perform free_containers.
      if sy-subrc = 0.
        set screen 0.
        leave screen.
      else.
        leave program.
      endif.
    when 'EXIT'.
      perform free_containers.
      leave program.
  endcase.
endmodule.
Regards,
Rich Heilman