How can I undelete an internal order - error KO444

Question

We have an internal order that is marked for deletion. I need to undelete to modify some of the content as it is being referenced by another process and causing an error
However when I go to KO02 I get error message
Order R00765436 is flagged as "deleted" -> display only
Message no. KO444
So I can't modify the order because it is flagged as deleted but I can't undelete as it is flagged as deleted !
ANyone know how I can undelete?

Answer 1

Run this program: ZKLOEKZ
*$*$                                                                $*$*
*$ Correction Inst.         0120024545 0000135593                     $*
*$                                                                    $*
*$ Valid for       :                                                  $*
*$ Software Component   SAP_APPL   SAP Application                    $*
*$  Release 30F          All Support Package Levels                   $*
*$  Release 31G          To SAPKH31G13                                $*
*$  Release 31H          All Support Package Levels                   $*
*$  Release 31I          All Support Package Levels                   $*
*$  Release 40A          To SAPKH40A25                                $*
*$  Release 40B          All Support Package Levels                   $*
*$  Release 45A          All Support Package Levels                   $*
*$  Release 45B          All Support Package Levels                   $*
*$  Release 46A          To SAPKH46A34                                $*
*$  Release 46B          All Support Package Levels                   $*
*$  Release 46C          All Support Package Levels                   $*
*$  Release 310          All Support Package Levels                   $*
*$  Release 470          All Support Package Levels                   $*
*$  Release 500          All Support Package Levels                   $*
*$  Release 600          All Support Package Levels                   $*
*$                                                                    $*
*$ Changes/Objects Not Contained in Standard SAP System               $*
*$*$                                                                $*$*
*& Object          REPS ZKLOEKZ
*& Object Header   PROG ZKLOEKZ
*& PROGRAM ZKLOEKZ
*>>>> START OF INSERTION <<<<
PROGRAM ZKLOEKZ.
TABLES: vsaufk, aufk.
SELECTION-SCREEN: ULINE,
                    COMMENT /1(72) LINE1,
                    COMMENT /1(72) LINE2,
                    COMMENT /1(72) LINE3,
                    COMMENT /1(72) LINE4,
                    ULINE, SKIP 1.
PARAMETERS:
   TESTMODE   DEFAULT 'X' AS CHECKBOX.
SELECT-OPTIONS:
   order     FOR vsaufk-aufnr MATCHCODE OBJECT orde.
DATA: count LIKE sy-dbcnt.
DATA: BEGIN OF auf OCCURS 1.
         INCLUDE STRUCTURE vsaufk.
DATA: END OF auf.
DATA: BEGIN OF status OCCURS 1.
         INCLUDE STRUCTURE jstat.
DATA: END OF status.
INITIALIZATION.
   MOVE 'ATTENTION !!!' TO LINE1.
   MOVE 'SAP does not accept responsibility for problems that' TO LINE2.
   MOVE 'might arise from the use of this report !' TO LINE3.
   MOVE 'Please see note 196637.' TO LINE4.
START-OF-SELECTION.
   SELECT * FROM vsaufk INTO TABLE auf
              WHERE aufnr IN ORDER
              AND   stat  = 'I0013'
              AND   ( autyp = '01' OR autyp = '04' )
              AND   loekz = 'X'.
   status-stat = 'I0013'.
   status-inact = 'X'.
   APPEND status.
   IF sy-subrc <> 0.
     WRITE 'No internal/CO-production orders found !'.
     EXIT.
   ENDIF.
   LOOP AT auf.
     CALL FUNCTION 'STATUS_CHECK'
       EXPORTING
         objnr             = auf-objnr
         status            = 'I0013'
       EXCEPTIONS
         status_not_active = 2.
     IF sy-subrc = 2.
       WRITE: / 'Order ', auf-aufnr, ': Deletion indicator not active.'.
       CONTINUE.
     ENDIF.
     IF testmode IS INITIAL.
       CALL FUNCTION 'ENQUEUE_ESORDER'
         EXPORTING
           aufnr        = auf-aufnr
         EXCEPTIONS
           foreign_lock = 1.
       IF sy-subrc <> 0.
         WRITE: / 'Order ', AUF-AUFNR, ' is currently blocked.'.
         CONTINUE.
       ENDIF.
       CALL FUNCTION 'STATUS_CHANGE_INTERN'
         EXPORTING
           objnr  = auf-objnr
         TABLES
           status = status.
       CHECK sy-subrc = 0.
       UPDATE aufk SET  aenam = sy-uname
                        aedat = sy-datum
               WHERE    aufnr = auf-aufnr.
       IF sy-subrc <> 0.
         WRITE: / 'Order ', auf-aufnr, ': Error during AUFK-Update.'.
       ENDIF.
     ENDIF.
     WRITE: / 'Order ', auf-aufnr, ': Deletion indicator removed.'.
     IF NOT testmode IS INITIAL.
       WRITE: ' - Testmode'.
     ENDIF.
     ADD 1 TO count.
     IF count = 100.
       IF TESTMODE IS INITIAL.
         COMMIT WORK.
       ENDIF.
       CLEAR count.
     ENDIF.
   ENDLOOP.
   IF TESTMODE IS INITIAL.
     COMMIT WORK.
   ENDIF.
   SKIP 1.
   WRITE: 'Program finished.'.
*>>>> END OF INSERTION <<<<<<