How can I use automator to import a .csv file into a an excel file

Question

I would still like all the import settings that I get if I am using excel to do the process, i.e. going in with the text format instead of the general format. That way my dates don't change

Answer 1

You'll need to use Applescript in Automator.
Note:  File extension cannot be CSV (Excel will assume that the file is comma separated), so add an action to copy or rename with extension TXT.
(You can rename back at end of Workflow is needed)
The Applescript Action is:
on run {input, parameters}
     repeat with f in input
          tell application "Microsoft Excel"
               open text file filename (f as string) data type delimited field info {{1, text format}} other char "|" with use other
          end tell
      end repeat
      eturn input
end run
NOTE: This is formating the 1st col to text
If you need to format the second, then you need to:
  open text file filename (f as string) data type delimited field info {{1, general format}, {2, text format}} other char "|" with use other
(You'll need to list the 1st col, 2nd col, etc until you get to the col to format as text).  Formats are (from the Applescript Excel Library):
[field info list] : A list contain parse information for the individual columns of data.
Formats are general format, text format, MDY format, DMY format, YMD format, MYD format, DYM format, YDM format, skip column.
Or you can skip using Automator and just use an Applescript App (this is a droplet, just drop the files on the icon, or click to choose files):
on run
     set fs to choose file with prompt "Select one or more files to open:" default location alias (the path to desktop folder as text) with multiple selections allowed
     proceed(fs)
end run
on open fs
     proceed(fs)
end open
on proceed(fs)
     repeat with f in fs
          tell application "Microsoft Excel"
               open text file filename (f as string) data type delimited field info {{1, text format}} other char "|" with use other
           end tell
      end repeat
end proceed