How do I move

Question

I am trying to create a dynamic internal table
  <b>        call method cl_alv_table_create=>create_dynamic_table
                         exporting it_fieldcatalog = gt_fieldcat
                         importing ep_table = gp_table.
          assign gp_table->* to <gt_table>.
          assign component l_index of structure <ls_table> to <l_field>.
          if sy-subrc eq 0.
          <l_field> = value.
          endif.
  append <ls_table> to <gt_table></b>
   I now want to append this <gt_table> into another internal table ITAB1 but the problem is I dont know how to declare this ITAB1? 
   DATA : ITAB1 type table : does not work???
   Please help.
   Thanks,
   Sanjay

Answer 1

Check this code for creating a dynamic internal table
REPORT ztest_gopi_dynamic.
TYPE-POOLS : abap.
FIELD-SYMBOLS: <dyn_table> TYPE STANDARD TABLE,
               <dyn_wa>,
               <dyn_field>.
DATA: dy_table TYPE REF TO data,
      dy_line  TYPE REF TO data,
      xfc TYPE lvc_s_fcat,
      ifc TYPE lvc_t_fcat.
SELECTION-SCREEN BEGIN OF BLOCK b1 WITH FRAME.
PARAMETERS: p_table(30) TYPE c DEFAULT 'T001'.
SELECTION-SCREEN END OF BLOCK b1.
START-OF-SELECTION.
  PERFORM get_structure.
  PERFORM create_dynamic_itab.
  PERFORM get_data.
  PERFORM write_out.
*       FORM get_structure                                            *
FORM get_structure.
  DATA : idetails TYPE abap_compdescr_tab,
         xdetails TYPE abap_compdescr.
  DATA : ref_table_des TYPE REF TO cl_abap_structdescr.
* Get the structure of the table.
  ref_table_des ?=
      cl_abap_typedescr=>describe_by_name( p_table ).
  idetails[] = ref_table_des->components[].
  LOOP AT idetails INTO xdetails.
    CLEAR xfc.
    xfc-fieldname = xdetails-name .
    xfc-datatype  = xdetails-type_kind.
    xfc-inttype   = xdetails-type_kind.
    xfc-intlen    = xdetails-length.
    xfc-decimals  = xdetails-decimals.
    APPEND xfc TO ifc.
  ENDLOOP.
ENDFORM.
*       FORM create_dynamic_itab                                      *
FORM create_dynamic_itab.
* Create dynamic internal table and assign to FS
  CALL METHOD cl_alv_table_create=>create_dynamic_table
               EXPORTING
                  it_fieldcatalog = ifc
               IMPORTING
                  ep_table        = dy_table.
  ASSIGN dy_table->* TO <dyn_table>.
* Create dynamic work area and assign to FS
  CREATE DATA dy_line LIKE LINE OF <dyn_table>.
  ASSIGN dy_line->* TO <dyn_wa>.
ENDFORM.
*       FORM get_data                                                 *
FORM get_data.
* Select Data from table.
  SELECT * INTO TABLE <dyn_table>
             FROM (p_table).
ENDFORM.
*       FORM write_out                                                *
FORM write_out.
* Write out data from table.
  LOOP AT <dyn_table> INTO <dyn_wa>.
    DO.
      ASSIGN COMPONENT  sy-index
         OF STRUCTURE <dyn_wa> TO <dyn_field>.
      IF sy-subrc <> 0.
        EXIT.
      ENDIF.
      IF sy-index = 1.
        WRITE:/ <dyn_field>.
      ELSE.
        WRITE: <dyn_field>.
      ENDIF.
    ENDDO.
  ENDLOOP.
ENDFORM.
Regards
Gopi