How do you shuffle the image order when creating a new slideshow in apterture 3? i would like to do this automatically when creating a new slideshow. i see how you do it when you just play a slideshow.

Question

how do you shuffle the image order when creating a new slideshow in apterture 3?  i would like to do this automatically when creating a new slideshow.  i see how you do it with presets when you just play a slideshow, but i don't see an option to randomly shuffle the slide order when you create a new slideshow.  i know you can sort it by different fields, but i want it to be random.  thanks.

Answer 1

If you want to rearrange images in random order you can try an AppleScript:
retrieve a list of selected images from Aperture
shuffe the list properly
create an album in Aperture and add the images from the list to the album (make sure that the album set to be orederd manually)
Here  is a sample script that shuffles the selected images and displays them in random order in Full Screen Mode:
on removeItem(ims, i)
  -- remove the item at position "i" from a list ims
          if ims is {} then return {}
          if (length of ims is 1) then return {}
          if i < 2 then return rest of ims
          if (i = length of ims) then return (items 1 thru (i - 1) of ims)
          if i > (length of ims) then return ims -- should be error?
          return (items 1 thru (i - 1) of ims) & (items (i + 1) thru (length of ims) of ims)
end removeItem
on shuffle_items(ims)
  -- shuffle the items of the list "ims" randomly
          local numitems, ims_shuffled, nextrest, nextpick, i
          set numitems to length of ims
          if length of ims < 2 then return ims
          set ims_shuffled to {}
          set nextrest to ims
          repeat until nextrest is {}
                    set i to (random number (numitems - 1)) + 1
                    set nextpick to item i of nextrest
                    set beginning of ims_shuffled to nextpick
                    set numitems to numitems - 1
                    set nextrest to removeItem(nextrest, i)
          end repeat
          return ims_shuffled
end shuffle_items
on shuffleIms()
  -- retrieve the selected images from Aperture
  -- and display them in random order in full screen mode
          local imageSel, shuffled, i
          tell application "Aperture"
  activate
                    set imageSel to (get selection)
                    set shuffled to my shuffle_items(imageSel)
                    set fullscreen to true
                    if imageSel is {} then error "Please select some images."
                    repeat with i from 1 to count of shuffled
                              reveal {item i of shuffled}
  delay 3 -- chnage that to the time you want
                    end repeat
                    set fullscreen to false
                    return shuffled
          end tell
end shuffleIms
shuffleIms()
Some more code snippets to go from here:
To create an album:
                    tell library 1
                              if not (exists album "shuffledAlbum") then
  make new album with properties {name:"shuffledAlbum", image version:shuffled}
                              end if
                    end tell
And to add the images from the shuffled list to the album:
                    repeat with i from 1 to count of shuffled
                              duplicate item i of shuffled to album "shuffledAlbum"
                    end repeat
Regards
Léonie