How do you sort numbers in the same field in excel 2010 the same for access 2010

Question

Hi,
Is there a way to sort data horizontally in the same field in excel and for access, or is there an addin that can do this
or  function code
field data    6-4-25-23-11-45
sort order 4-6-11-23-25-45
Regards,
Rudolf
rudolfelizabeth

Answer 1

sort data horizontally in the same field in excel
Does "in the same field" means that the string "6-4-25-23-11-45" is located in one cell?
In that case you have to use an UDF. Paste this code into a regular module:
Function SortNumbersPrim(ByVal What As String, Optional ByVal Delimiter) As Variant
  Dim Arr, Temp
  Dim i As Long, j As Long
  Arr = Split(What, Delimiter)
  For i = LBound(Arr) + 1 To UBound(Arr)
    Temp = Val(Arr(i))
    For j = i - 1 To LBound(Arr) Step -1
      If Val(Arr(j)) <= Temp Then Exit For
      Arr(j + 1) = Arr(j)
    Next
    Arr(j + 1) = Temp
  Next
  SortNumbersPrim = Join(Arr, Delimiter)
End Function
Then use a formula like this:
=SortNumbersPrim(A1,"-")
Andreas.