How to add records or how to maintain list in stored Procedure

Question

Hi,
I am facing an issue in the addition of record in the type
create or replace
TYPE               "PROD_SEARCH_COUNT_TBL"                                          AS TABLE OF PROD_SEARCH_COUNT_OBJ;
create or replace
TYPE               "PROD_SEARCH_COUNT_OBJ"                                          AS OBJECT
( /* TODO enter attribute and method declarations here */
    V_Name Varchar2(500 Byte),
    v_Value Varchar2(500 Byte),
    v_count Number
I want to add records to the type I tried following way
prod_wcf_rec PROD_SEARCH_COUNT_TBL;
  SELECT PROD_SEARCH_COUNT_OBJ('Name1','Value1',1) BULK COLLECT INTO prod_wcf_rec FROM DUAL;
    SELECT PROD_SEARCH_COUNT_OBJ('Name2','Value2',2) BULK COLLECT INTO prod_wcf_rec FROM DUAL;
    SELECT PROD_SEARCH_COUNT_OBJ('Name3','Value3',3) BULK COLLECT INTO prod_wcf_rec FROM DUAL;
    SELECT PROD_SEARCH_COUNT_OBJ('Name4','Value4',4) BULK COLLECT INTO PROD_WCF_REC FROM DUAL;
DBMS_OUTPUT.PUT_LINE ('-----------------------------Looping----------------------------');
FOR i in 1 .. prod_wcf_rec.COUNT
LOOP         
DBMS_OUTPUT.PUT_LINE (prod_wcf_rec(i).V_Name||' - '||prod_wcf_rec(i).v_Value||' - '||prod_wcf_rec(i).v_count);     
   END LOOP;
   DBMS_OUTPUT.PUT_LINE ('-----------------------------Looping----------------------------');
In printing I am getting last records only .So is there any way to add records to PROD_SEARCH_COUNT_TBL
How to add records or how to maintain list in stored Procedure

Answer 1

Every time you BULK COLLECT into a collection type the value is overwirtten. So you need to try something like this.
SQL> create or replace type prod_search_count_obj as object(v_name varchar2(500 byte), v_value varchar2(500 byte), v_count number)
  2  /
Type created.
SQL> create or replace type prod_search_count_tbl as table of prod_search_count_obj
  2  /
Type created.
SQL> declare
  2    prod_wcf_rec prod_search_count_tbl;
  3  begin
  4    select obj_val
  5      bulk collect into prod_wcf_rec
  6      from (
  7            select prod_search_count_obj('name1','value1',1) obj_val from dual
  8            union all
  9            select prod_search_count_obj('name2','value2',2) from dual
10            union all
11            select prod_search_count_obj('name3','value3',3) from dual
12            union all
13            select prod_search_count_obj('name4','value4',4) from dual
14           );
15
16    dbms_output.put_line ('-----------------------------looping----------------------------');
17    for i in 1 .. prod_wcf_rec.count
18    loop
19      dbms_output.put_line (prod_wcf_rec(i).v_name||' - '||prod_wcf_rec(i).v_value||' - '||prod_wcf_rec(i).v_count);
20    end loop;
21    dbms_output.put_line ('-----------------------------looping----------------------------');
22  end;
23  /
-----------------------------looping----------------------------
name1 - value1 - 1
name2 - value2 - 2
name3 - value3 - 3
name4 - value4 - 4
-----------------------------looping----------------------------
PL/SQL procedure successfully completed.
SQL>