How to catch "an insufficient number of arguments" error?

Question

Hi All,
I have a question - how to cauch this error:
SELECT * FROM dbo.ExistingFunction ('Wrong number of params - ExistingFunction expects 2 of them')
I tried using try-catch (both on the same level and one level higher) but with no success.
Best Regards,
Mike

Answer 1

There are a couple of variations with this error, because it depends on when the mismatch between the caller and the function occurs.
1) The function call is incorrect when you attempt to create the procedure => the procedure will not be created.
2) The function was correct when you created the procedure, but the function was changed before the procedure was compiled and put into cache. In this case compilation of the procedure fails, and it is never entered. And thus you cannot trap it in the procedure
itself. You can catch it in outer scope.
3) The function was changed after the procedure was put into cache. This causes a statement recompile at run-time, and as will all compilation errors, you cannot catch this in the local CATCH block despite you have entered the TRY block. You cannot however
trap it in the caller.
You say that you are not trap it even one level higher, but that is certainly possible, as testified by the repro below:
[sql]
CREATE FUNCTION funkis (@a int)
RETURNS @r TABLE (a int) AS
BEGIN
   INSERT @r VALUES(@a + 1)
   RETURN
END
go
CREATE PROCEDURE inner_sp AS
BEGIN TRY
   PRINT 'Entering inner_sp'
   SELECT * FROM dbo.funkis(1)
   PRINT 'Exiting inner_sp'
END TRY
BEGIN CATCH
   PRINT 'Error trapped in inner_sp: ' + error_message()
END CATCH
go
CREATE PROCEDURE outer_sp AS
BEGIN TRY
   PRINT 'Entering outer_sp'
   EXEC inner_sp
   PRINT 'Exiting outer_sp'
END TRY
BEGIN CATCH
   PRINT 'Error trapped in outer_sp: ' + error_message()
END CATCH
go
EXEC outer_sp
PRINT '------------------------'
go
ALTER FUNCTION funkis (@a int, @b int)
RETURNS @r TABLE (a int) AS
BEGIN
   INSERT @r VALUES(@a + @b)
   RETURN
END
go
EXEC outer_sp
go
DROP FUNCTION funkis
DROP PROCEDURE inner_sp, outer_sp
[sql]
Erland Sommarskog, SQL Server MVP, [email protected]