How to check particluar string in xml data

Question

Dear oracle Experts.
Im using the following oracle database.
Oracle Database 10g Enterprise Edition Release 10.2.0.4.0 - 64bi
PL/SQL Release 10.2.0.4.0 - Production
CORE 10.2.0.4.0 Production
TNS for Linux: Version 10.2.0.4.0 - Production
NLSRTL Version 10.2.0.4.0 - Production
I have a following xml data..
p_msg_in CLOB :=
<DATA>
<FLD FNR="ZZ0584" DTE="26SEP12" SRC="DXB" DES="DAC" />
<AAA LBP="22334455" ETK="1234567/4" ACT="123" />
<AAA LBP="223344" ETK="2345678/1" />
<AAA LBP="223344" ETK="123456/1" ACT="345" />
</DATA>
then, im fetching header details like this..
v_msg_xml := xmltype(p_msg_in);
FOR i IN multicur(v_msg_xml, '/DATA/FLD') LOOP
v_1:= i.xml.extract('//@FNR').getstringval();
v_4:= to_date(i.xml.extract('//@DTE').getstringval(),'DDMONYY');
v_5:= i.xml.extract('//@SRC').getstringval();
v_6:= i.xml.extract('//@DES').getstringval();
END LOOP;
after this, I need to loop all the actual records one by one using this for loop. Here for each iteration , i need to check some string ( example ACT) is there or not. in the above example, records 1,3 have ACT value in it. So here i need to check some thing like this. if instr('<AAA LBP="223344" ETK="123456/1" ACT="345" />','ACT)>0 before I perform the below step.
How to achieve this.
I appreciate your help.
thank you.
FOR c IN multicur(v_msg_xml, '/DATA/AAA') LOOP
v_7 := c.xml.extract('//@LBP').getstringval();
v_8 := c.xml.extract('//@ETK').getstringval();

Answer 1

SQL> DECLARE
  2 
  3    p_msg_in  clob := '<DATA>
  4  <FLD FNR="ZZ0584" DTE="26SEP12" SRC="DXB" DES="DAC" />
  5  <AAA LBP="22334455" ETK="1234567/4" ACT="123" />
  6  <AAA LBP="223344" ETK="2345678/1" />
  7  <AAA LBP="223344" ETK="123456/1" ACT="345" />
  8  </DATA>';
  9 
10    v_msg_xml xmltype;
11 
12    v_1       varchar2(30);
13    v_4       date;
14    v_5       varchar2(30);
15    v_6       varchar2(30);
16    v_7       varchar2(30);
17    v_8       varchar2(30);
18 
19  BEGIN
20 
21    v_msg_xml := xmltype(p_msg_in);
22 
23    select fnr, to_date(dte, 'DDMONRR'), src, des
24    into v_1, v_4, v_5, v_6
25    from xmltable('/DATA/FLD'
26           passing v_msg_xml
27           columns fnr  varchar2(30) path '@FNR'
28                 , dte  varchar2(30) path '@DTE'
29                 , src  varchar2(30) path '@SRC'
30                 , des  varchar2(30) path '@DES'
31         ) ;
32 
33     dbms_output.put_line('V1 = '||v_1);
34     dbms_output.put_line('V4 = '||v_4);
35     dbms_output.put_line('V5 = '||v_5);
36     dbms_output.put_line('V6 = '||v_6);
37 
38     for r in (
39       select lbp, etk
40       from xmltable('/DATA/AAA[@ACT]'
41              passing v_msg_xml
42              columns lbp  varchar2(30) path '@LBP'
43                    , etk  varchar2(30) path '@ETK'
44            )
45     )
46     loop
47       dbms_output.put_line('LBP = '||r.lbp||' ETK = '||r.etk);
48     end loop;
49 
50  END;
51  /
V1 = ZZ0584
V4 = 26/09/12
V5 = DXB
V6 = DAC
LBP = 22334455 ETK = 1234567/4
LBP = 223344 ETK = 123456/1
PL/SQL procedure successfully completed