How to covert csv to Excel 2007

Question

Hello
Can anyone knows that how to convert the CSV file to the EXCEL 2007 format (xlsx ) not to excel 2003(xls) .

Answer 1

Hi,
If you want to create a real Excel file, the easiest way is certainly to use XML. With the Microsoft documentation and some retro engeneering you should be able to produce XLS files matching your needs. Creating XLSX is possible (I made it for DOCX files), this is however much more complicated.
Hope this will help you.
REPORT  test.
DATA: gt_spfli         TYPE STANDARD TABLE OF spfli,
      gr_spfli         TYPE REF TO spfli,
      gv_xls_template  TYPE string,
      go_xls_xml       TYPE REF TO cl_xml_document,
      go_table_element TYPE REF TO if_ixml_element,
      go_row_element   TYPE REF TO if_ixml_element,
      go_cell_element  TYPE REF TO if_ixml_element,
      go_data_element  TYPE REF TO if_ixml_element,
      gv_cell_value    TYPE string,
      gv_nb_rows       TYPE string,
      gv_nb_columns    TYPE string.
"1. Get some test data
SELECT * INTO TABLE gt_spfli FROM spfli.
"2. XML Excel file template creation
CONCATENATE `<?xml version="1.0"?>`
            `<?mso-application progid="Excel.Sheet"?>`
            `<Workbook xmlns="urn:schemas-microsoft-com:office:spreadsheet"`
             `xmlns:o="urn:schemas-microsoft-com:office:office"`
             `xmlns:x="urn:schemas-microsoft-com:office:excel"`
             `xmlns:ss="urn:schemas-microsoft-com:office:spreadsheet"`
             `xmlns:html="http://www.w3.org/TR/REC-html40">`
             `<DocumentProperties xmlns="urn:schemas-microsoft-com:office:office">`
            ` </DocumentProperties>`
            ` <ExcelWorkbook xmlns="urn:schemas-microsoft-com:office:excel">`
            `  <WindowHeight>12525</WindowHeight>`
            `  <WindowWidth>15195</WindowWidth>`
            `  <WindowTopX>480</WindowTopX>`
            `  <WindowTopY>120</WindowTopY>`
            `  <ProtectStructure>False</ProtectStructure>`
            `  <ProtectWindows>False</ProtectWindows>`
            ` </ExcelWorkbook>`
            ` <Styles>`
            `  <Style ss:ID="Default" ss:Name="Normal">`
            `   <Alignment ss:Vertical="Bottom"/>`
            `   <Borders/>`
            `   <Font/>`
            `   <Interior/>`
            `   <NumberFormat/>`
            `   <Protection/>`
            `  </Style>`
            ` </Styles>`
            ` <Worksheet ss:Name="Feuil1">`
            `  <Table x:FullColumns="1" x:FullRows="1" ss:DefaultColumnWidth="60">`
            `  </Table>`
            `  <WorksheetOptions xmlns="urn:schemas-microsoft-com:office:excel">`
            `   <PageSetup>`
            `    <Header x:Margin="0.4921259845"/>`
            `    <Footer x:Margin="0.4921259845"/>`
            `    <PageMargins x:Bottom="0.984251969" x:Left="0.78740157499999996"`
            `     x:Right="0.78740157499999996" x:Top="0.984251969"/>`
            `   </PageSetup>`
            `   <Selected/>`
            `   <ProtectObjects>False</ProtectObjects>`
            `   <ProtectScenarios>False</ProtectScenarios>`
            `  </WorksheetOptions>`
            ` </Worksheet>`
            `</Workbook>` INTO gv_xls_template.
"3. Transform the XML String to a real XML document
CREATE OBJECT go_xls_xml.
go_xls_xml->parse_string( stream = gv_xls_template ).
CLEAR gv_xls_template. "No more required
"4. Retrieve the Table node. We will populate this node with the cell's content later on
go_table_element ?= go_xls_xml->find_node( name = '/Workbook/Worksheet/Table' ).
"5. Populating the file with data
LOOP AT gt_spfli REFERENCE INTO gr_spfli.
  "5.1 Creation of a new <Row> tag
  go_row_element ?= go_xls_xml->create_simple_element( name = 'Row' parent = go_table_element ).
  "5.2. Creation of a new <Cell><Data ss:Type="String">my value</Data></Cell>
  "5.2.1. Carrid to String casting
  gv_cell_value = gr_spfli->carrid.
  "5.2.2. <Cell><Data>$gv_cell_value</Data></Cell>
  go_cell_element ?= go_xls_xml->create_simple_element( name = 'Cell' parent = go_row_element ).
  go_data_element ?= go_xls_xml->create_simple_element( name = 'Data' parent = go_cell_element value = gv_cell_value ).
  "5.2.3. Add type description to the <Data> tag
  go_data_element->set_attribute_ns( name = 'Type' prefix = 'ss' value = 'String' ).
ENDLOOP.
"6. Add the number of rows and columns to the <Table> tag
gv_nb_rows = LINES( gt_spfli ). "Number of rows to be displayed
gv_nb_columns = 1. "Number of columns to displayed
CONDENSE: gv_nb_columns NO-GAPS, gv_nb_rows NO-GAPS.
go_table_element->set_attribute_ns( name = 'ExpandedColumnCount' prefix = 'ss' value = gv_nb_columns ).
go_table_element->set_attribute_ns( name = 'ExpandedRowCount' prefix = 'ss' value = gv_nb_rows ).
"7. Display or download the file
"go_xls_xml->display( ).
go_xls_xml->export_to_file( 'C:/temp/spfli.xls' ).