How to create downloadable pdf report as hyperlink within BSP application

Question

Hi,
I'm developing a BSP application using MVC and htmlb extensions on a WAS 6.40. One of the requirements of my webapplication is:
- the ability to generate a report in pdf format at runtime, using data retrieved from a backend SAP CRM 3.0 system
and
- make this report available/downloadable via a hyperlink in the application.
I am aware of tools like Smartforms and Adobe interactive forms but need some help to get started and choose the right tool.
regards, Roelof Jan

Answer 1

Hi,
we've done that by firstly building a RFC which prints the report to sap-spool:
call function 'GET_PRINT_PARAMETERS'
      exporting
        expiration     = 1
        immediately    = ' '
        new_list_id    = 'X'
        line_count     = 65
        line_size      = 132
        report         = sy-repid
        no_dialog      = 'X'
      importing
        out_parameters = wf_params
        valid          = valid_flag.
    if sy-subrc ne 0 or valid_flag eq false.
    endif.
    new-page no-heading no-title print on parameters wf_params
                      no dialog .
... list processing ...
new-page print off.
  concatenate programname sy-uname+0(3) into lc_rq2name separated by '_'.
  select * from tsp01 into tsp01_wa
                      where rq2name = lc_rq2name
                      and rqowner   = sy-uname
                      order by rqcretime descending.
    wf_spono = tsp01_wa-rqident.
    exit.
  endselect.
  if sy-subrc ne 0.
    clear wf_spono.
  endif.
Then convert the spooljob:
  call function 'CONVERT_ABAPSPOOLJOB_2_PDF'
    exporting
      src_spoolid              = wf_spono
      no_dialog                = 'X'
    tables
      pdf                      = witab
    exceptions
      err_no_abap_spooljob     = 1
      err_no_spooljob          = 2
      err_no_permission        = 3
      err_conv_not_possible    = 4
      err_bad_destdevice       = 5
      user_cancelled           = 6
      err_spoolerror           = 7
      err_temseerror           = 8
      err_btcjob_open_failed   = 8
      err_btcjob_submit_failed = 9
      err_btcjob_close_failed  = 10
      others                   = 11.
  if sy-subrc ne 0.
    return.
  endif.
Delete Spooljob and generate cached response:
  data del_spono type  tsp01_sp0r-rqid_char.
  del_spono = wf_spono.
  call function 'RSPO_R_RDELETE_SPOOLREQ'
    exporting
      spoolid = del_spono.
  if witab is not initial.
    loop at witab into itab .
      translate itab using ' ~'.
      concatenate output itab into output in character mode.
    endloop.
    translate output using '~ ' .
    create object cached_response
           type cl_http_response
           exporting add_c_msg = 1.
    l_pdf_len = strlen( output ).
    cached_response->set_cdata( data   = output
                                length = l_pdf_len ).
    cached_response->set_header_field( name  = if_http_header_fields=>content_type
                                       value = 'application/pdf' ).
    cached_response->set_status( code = 200 reason = 'OK' ).
    cached_response->server_cache_expire_rel( expires_rel = 180 ).
    data: guid type guid_32,
          display_url type string.
    call function 'GUID_CREATE'
      importing
        ev_guid_32 = guid.
    concatenate runtime->application_url '/' guid '.pdf'
                into display_url.
    cl_http_server=>server_cache_upload( url      = display_url
                                         response = cached_response ).
    app ?= application.
    app->print_url = display_url.
  endif .
The display_url has to be used in the normal response-view:
<script type="text/javascript">
var param = 'width=700'
      + ',height=550'
      + ',left=0'
      + ',top=0'
      + ',menubar=no'
      + ',location=no'
      + ',resizable=yes'
      + ',status=no';
  window.open('<%= application->print_url%>', 'DRUCK', param ).focus();
</script>