How to define a function with table type parameter

Question

Hello All,
Here is the requirement ..
cursor c is select first_name, last_name , ssn from employee ;
TYPE employee_type IS TABLE OF c%rowtype;
tbl_employee_type employee_type;
I want to pass the parameter to a function the ssn -: tbl_employee_type(1).ssn
how the formal parameter should be declared
===========================
function chk_notnull_blank ( ? ) return boolean is
BEGIN
if ( colname is NOT NULL and colname in ( -8E14, -7E14, -6E14, -5E14, -4E14, -3E14, -2E14, -1E14, -1E9 )) then
RETURN TRUE ;
else
RETURN FALSE ;
end if;
END chk_notnull_blank;
======================
pls advice
thanks/kumar

Answer 1

You cannot define a generic argument in a function,
but you can overload several funtions with the same name and different types of arguments in a package,
in this way (not tested):
create table employees as
select employee_id ssn, first_name, last_name from hr.employees;
create or replace
PACKAGE chk
IS
  cursor c is select first_name, last_name , ssn from employees ;
  TYPE employee_type IS TABLE OF c%rowtype;
  TYPE employee_ssn_type IS TABLE OF employees.ssn%TYPE;
  TYPE employee_num_type IS TABLE OF number;
  FUNCTION chk_notnull_blank ( colname  employees.ssn%TYPE) RETURN boolean;
  FUNCTION chk_notnull_blank ( colnames  employee_type) RETURN boolean;
  FUNCTION chk_notnull_blank ( colnames  employee_ssn_type) RETURN boolean;
  FUNCTION chk_notnull_blank ( colnames  employee_num_type) RETURN boolean;
END chk;
create or replace
PACKAGE BODY chk
IS
  FUNCTION chk_notnull_blank ( colname  employees.ssn%TYPE) RETURN boolean IS
  BEGIN
    if ( colname is NOT NULL and colname in ( -8E14, -7E14, -6E14, -5E14, -4E14, -3E14, -2E14, -1E14, -1E9 )) then
      RETURN TRUE ;
    else
      RETURN FALSE ;
    END IF;
  END chk_notnull_blank;
  FUNCTION chk_notnull_blank ( colnames  employee_type) RETURN boolean IS
  BEGIN
     FOR i IN colnames.FIRST .. colnames.LAST LOOP
        IF NOT chk_notnull_blank( colnames( i ).ssn )
        THEN
           RETURN FALSE;
        END IF;
     END LOOP;
     RETURN true;
  END chk_notnull_blank;
  FUNCTION chk_notnull_blank ( colnames  employee_ssn_type) RETURN boolean
  IS
  BEGIN
     FOR i IN colnames.FIRST .. colnames.LAST LOOP
        IF NOT chk_notnull_blank( colnames( i ) )
        THEN
           RETURN FALSE;
        END IF;
     END LOOP;
     RETURN TRUE;
  END chk_notnull_blank; 
  FUNCTION chk_notnull_blank ( colnames  employee_num_type) RETURN boolean
  IS
  BEGIN
     FOR i IN colnames.FIRST .. colnames.LAST LOOP
        IF NOT chk_notnull_blank( colnames( i ) )
        THEN
           RETURN FALSE;
        END IF;
     END LOOP;
     RETURN TRUE;
  END chk_notnull_blank; 
END chk;I assumed in this example that if the argument of the function chk_notnull_blank is of the table (collection) type,
then the function returns true if all table elements pass the check, otherwise it returns false.