How to download an image from SAP to my PC?

Question

Hello SAPients.
I know that I can upload an image to SAP using transaction SE78, but now I need the inverse process, I mean, download an image from SAP to my PC. How can I do this?
Thanks in advance for your help.

Answer 1

The following program codes allow you to download SAP images stored in SE78 and the traditional SO10:
*& Report  Z_DOWNLOAD_BDS_GRAPHICS
*& Download image stored in document server
*& Published at ****************
REPORT  z_download_bds_graphics                 .
* Variable declaration
DATA: v_graphic_size TYPE i,
      v_graphic_xstr TYPE xstring,
      v_graphic_conv TYPE i,
      v_graphic_offs TYPE i,
      v_file         TYPE string.
* Table declaration
DATA: BEGIN OF i_graphic_table OCCURS 0,
        line(255) TYPE x,
      END OF i_graphic_table.
DATA: lt_tline type table of tline with header line.
data: l_thead type thead.
* Structure declaration
DATA: st_stxbitmaps       TYPE stxbitmaps.
* Selection screen
PARAMETERS: P_SO10 RADIOBUTTON GROUP RB1.
SELECTION-SCREEN BEGIN OF BLOCK b2 WITH FRAME TITLE text-002.
PARAMETERS: p_TDID     LIKE THEAD-TDID DEFAULT 'ADRS',
            p_TDNAME   LIKE THEAD-TDNAME,
            p_TDOBJ    LIKE THEAD-TDOBJECT DEFAULT 'TEXT',
            p_TDSPRA   LIKE THEAD-TDSPRAS DEFAULT 'EN'.
SELECTION-SCREEN END OF BLOCK b2.
PARAMETERS: p_se78 RADIOBUTTON GROUP RB1.
SELECTION-SCREEN BEGIN OF BLOCK b1 WITH FRAME TITLE text-001.
PARAMETERS: p_object LIKE st_stxbitmaps-tdobject DEFAULT 'GRAPHICS'
                              MODIF ID abc ,
            p_name   LIKE st_stxbitmaps-tdname,
            p_id     LIKE st_stxbitmaps-tdid DEFAULT 'BMAP'
                              MODIF ID abc ,
            p_type   LIKE st_stxbitmaps-tdbtype.
SELECTION-SCREEN END OF BLOCK b1.
PARAMETERS: p_dir    TYPE localfile DEFAULT 'D:\GIS'.
* At Selection-screen output event
AT SELECTION-SCREEN OUTPUT.
  LOOP AT SCREEN.
    IF screen-group1 = 'ABC' .
      screen-input = '0'.
      MODIFY SCREEN.
    ENDIF.
  ENDLOOP.
* At Selection-screen on value-request event
AT SELECTION-SCREEN ON VALUE-REQUEST FOR p_dir.
  DATA: l_folder TYPE string.
  CALL METHOD cl_gui_frontend_services=>directory_browse
    EXPORTING
      window_title         = 'Select Folder'
      initial_folder       = 'C:\'
    CHANGING
      selected_folder      = l_folder
    EXCEPTIONS
      cntl_error           = 1
      error_no_gui         = 2
      not_supported_by_gui = 3
      OTHERS               = 4.
  IF sy-subrc = 0.
    p_dir = l_folder.
  ENDIF.
* Start-of-selection event
START-OF-SELECTION.
  IF p_se78 = 'X'.
    st_stxbitmaps-tdobject = p_object.
    st_stxbitmaps-tdname = p_name.
    st_stxbitmaps-tdid = p_id.
    st_stxbitmaps-tdbtype = p_type.
*   Get the bmp image from BDS in hex string format
    CALL METHOD cl_ssf_xsf_utilities=>get_bds_graphic_as_bmp
      EXPORTING
        p_object       = st_stxbitmaps-tdobject
        p_name         = st_stxbitmaps-tdname
        p_id           = st_stxbitmaps-tdid
        p_btype        = st_stxbitmaps-tdbtype
      RECEIVING
        p_bmp          = v_graphic_xstr
      EXCEPTIONS
        not_found      = 1
        internal_error = 2
        OTHERS         = 3.
    IF sy-subrc = 0.
*     Find the length of hex string
      v_graphic_size = xstrlen( v_graphic_xstr ).
      CHECK v_graphic_size > 0.
      v_graphic_conv = v_graphic_size.
      v_graphic_offs = 0.
*     Populate internal table from this hex string
      WHILE v_graphic_conv > 255.
        i_graphic_table-line = v_graphic_xstr+v_graphic_offs(255).
        APPEND i_graphic_table.
        v_graphic_offs = v_graphic_offs + 255.
        v_graphic_conv = v_graphic_conv - 255.
      ENDWHILE.
     i_graphic_table-line = v_graphic_xstr+v_graphic_offs(v_graphic_conv).
      APPEND i_graphic_table.
*     Prepare file name and file path
      CONCATENATE p_dir '\' p_name '.BMP' INTO v_file.
*     Download image
      CALL FUNCTION 'GUI_DOWNLOAD'
        EXPORTING
          bin_filesize            = v_graphic_size
          filename                = v_file
          filetype                = 'BIN'
        TABLES
          data_tab                = i_graphic_table
        EXCEPTIONS
          file_write_error        = 1
          no_batch                = 2
          gui_refuse_filetransfer = 3
          invalid_type            = 4
          no_authority            = 5
          unknown_error           = 6
          header_not_allowed      = 7
          separator_not_allowed   = 8
          filesize_not_allowed    = 9
          header_too_long         = 10
          dp_error_create         = 11
          dp_error_send           = 12
          dp_error_write          = 13
          unknown_dp_error        = 14
          access_denied           = 15
          dp_out_of_memory        = 16
          disk_full               = 17
          dp_timeout              = 18
          file_not_found          = 19
          dataprovider_exception  = 20
          control_flush_error     = 21
          OTHERS                  = 22.
      IF sy-subrc = 0.
        WRITE: 'File downloaded successfully'(003), v_file.
      ELSE.
        WRITE: 'Error during file download'(004).
      ENDIF.
    ELSE.
      CASE sy-subrc.
        WHEN 1.
          WRITE: 'Image not found'(005).
        WHEN OTHERS.
          WRITE: 'Error in Image retrieval'(006).
      ENDCASE.
    ENDIF.
  ENDIF. "IF P_SE78 = 'X'.
  IF P_SO10 = 'X'.
    CALL FUNCTION 'READ_TEXT'
      EXPORTING
*       CLIENT                        = SY-MANDT
        ID                            = p_TDID
        LANGUAGE                      = p_TDSPRA
        NAME                          = p_TDNAME
        OBJECT                        = p_TDOBJ
*       ARCHIVE_HANDLE                = 0
*       LOCAL_CAT                     = ' '
      IMPORTING
        HEADER                        = l_thead
      TABLES
        LINES                         = lt_tline
      EXCEPTIONS
         ID                            = 1
         LANGUAGE                      = 2
         NAME                          = 3
         NOT_FOUND                     = 4
         OBJECT                        = 5
         REFERENCE_CHECK               = 6
         WRONG_ACCESS_TO_ARCHIVE       = 7
         OTHERS                        = 8
    IF SY-SUBRC <> 0.
          WRITE: 'Image not found'(005).
    ENDIF.
CALL FUNCTION 'SAPSCRIPT_CONVERT_BITMAP'
  EXPORTING
    ITF_HEADER                     = l_thead
    OLD_FORMAT                     = 'ITF'
    NEW_FORMAT                     = 'BMP'
    BITMAP_FILE_BYTECOUNT_IN       = 0
    ITF_BITMAP_TYPE_IN             = '*'
IMPORTING
   BITMAP_FILE_BYTECOUNT          = v_graphic_size
*   ITF_BITMAP_TYPE_OUT            =
  TABLES
    ITF_LINES                      = lt_tline
    BITMAP_FILE                    = i_graphic_table
*   BDS_BITMAP_FILE                =
  EXCEPTIONS
    NO_BITMAP_FILE                 = 1
    FORMAT_NOT_SUPPORTED           = 2
    BITMAP_FILE_NOT_TYPE_X         = 3
    NO_BMP_FILE                    = 4
    BMPERR_INVALID_FORMAT          = 5
    BMPERR_NO_COLORTABLE           = 6
    BMPERR_UNSUP_COMPRESSION       = 7
    BMPERR_CORRUPT_RLE_DATA        = 8
    BMPERR_EOF                     = 9
    BDSERR_INVALID_FORMAT          = 10
    BDSERR_EOF                     = 11
    OTHERS                         = 12
IF SY-SUBRC <> 0.
          WRITE: 'Error in Image Format'(006).
ENDIF.
    if sy-subrc = 0.
      CONCATENATE p_dir '\' p_TDNAME '.BMP' INTO v_file.
*     Download image
      CALL FUNCTION 'GUI_DOWNLOAD'
        EXPORTING
          bin_filesize            = v_graphic_size
          filename                = v_file
          filetype                = 'BIN'
        TABLES
          data_tab                = i_graphic_table
        EXCEPTIONS
          file_write_error        = 1
          no_batch                = 2
          gui_refuse_filetransfer = 3
          invalid_type            = 4
          no_authority            = 5
          unknown_error           = 6
          header_not_allowed      = 7
          separator_not_allowed   = 8
          filesize_not_allowed    = 9
          header_too_long         = 10
          dp_error_create         = 11
          dp_error_send           = 12
          dp_error_write          = 13
          unknown_dp_error        = 14
          access_denied           = 15
          dp_out_of_memory        = 16
          disk_full               = 17
          dp_timeout              = 18
          file_not_found          = 19
          dataprovider_exception  = 20
          control_flush_error     = 21
          OTHERS                  = 22.
      IF sy-subrc = 0.
        WRITE: 'File downloaded successfully'(003), v_file.
      ELSE.
        WRITE: 'Error during file download'(004).
      ENDIF.
    endif.
  ENDIF.