How to find multiple keys in single cell using Numbers?

Question

I'm trying to add functionality to one of my Numbers tables where want to check a single cell for multiple keywords from a list. The hole thing works perfectly fine in Excel but it behaves differently in Numbers.
The formula I am using is:
=IF(ISERROR(LOOKUP(2^15;FIND($E$2:$E$11;A2)));"not found";"found")
The following screenshots show that it correctly finds the keys in the cell when using Excel but not in Numbers. Although, it seems to work if the key is in the same row as the input cell.
Excel table using the formula I posted in the C column:
Numbers table using the formula I posted in the C column:
Would be really happy if somebody knows how I could accomplish that!
Cheers,
Maik

Answer 1

If you are working in Numbers you can do this efficiently with a small AppleScript without going back to Excel or clone. One click and you get the following result:
This script works with Numbers 2.3, which your screenshot suggests you are using. If you are using Numbers 3 it needs a very small adjustment.
This is the script:
--https://discussions.apple.com/thread/6315365?tstart=30
property inputCol : 1 --> col A, as in example
property resultCol : 3 --> col C, as in example
property keysCol : 5 --> col E, as in example
property targDoc : 1 --> 1 is front document; can change to "MyDocName"
property targSheet : 1 --> 1 is first sheet; can change to "MySheetName"
property targTable : 1 --> 1 is first table; can change to "MyTableName"
tell application "Numbers"
          set t to document targDoc's sheet targSheet's table targTable
          set keysList to t's column keysCol's cells's value
          repeat with i from 2 to t's row count -- assumes 1 Header Row
                    set inputVal to t's row i's cell inputCol's value
                    if inputVal is not 0 then --skip blank cells; Numbers 2 reads blanks as 0
                              --check if Input matches a key:
                              if inputVal is in keysList then
                                        set t's row i's cell resultCol's value to "found"
                              else
                                        set t's row i's cell resultCol's value to "not found"
                              end if
                              --check if Input contains a key:
                              repeat with aKey in keysList
                                        if inputVal contains aKey then set t's row i's cell resultCol's value to "found"
                              end repeat
                    end if
          end repeat
end tell
--end of script
To run, copy into AppleScript Editor, change the properties if needed, and click the green triangle 'Run' botton.
SG