How to insert 10 rows at a time in the oracle

Question

how ti insert r update 10 query at a time in the oracle

Answer 1

You can do a small test to find it out.
SQL> set serveroutput on
SQL> drop table t
  2  /
Table dropped.
SQL> drop table s
  2  /
Table dropped.
SQL> create table s(no integer, name varchar2(4000))
  2  /
Table created.
SQL> create table t(no integer, name varchar2(4000))
  2  /
Table created.
SQL> insert into s
  2  select level, rpad('*',4000,'*')
  3    from dual
  4  connect by level <= 10000
  5  /
10000 rows created.
SQL> commit
  2  /
Commit complete.
SQL> declare
  2     ltime integer;
  3  begin
  4     ltime := dbms_utility.get_time;
  5
  6     for i in (select * from s)
  7     loop
  8             insert into t(no, name) values(i.no,i.name);
  9     end loop;
10
11     ltime := dbms_utility.get_time - ltime;
12
13     dbms_output.put_line('Exec Time:'||ltime/100||' Seconds...');
14     commit;
15  end;
16  /
Exec Time:17.22 Seconds...
PL/SQL procedure successfully completed.
SQL> truncate table t
  2  /
Table truncated.
SQL> declare
  2     type my_type is table of s%rowtype;
  3     lType my_type;
  4     ltime integer;
  5  begin
  6     ltime := dbms_utility.get_time;
  7
  8     select * bulk collect into lType from s;
  9
10     forall i in 1..lType.count
11             insert into t values lType(i);
12
13     ltime := dbms_utility.get_time - ltime;
14
15     dbms_output.put_line('Exec Time:'||ltime/100||' Seconds...');
16
17     commit;
18  end;
19  /
Exec Time:6.27 Seconds...
PL/SQL procedure successfully completed.
SQL> truncate table t
  2  /
Table truncated.
SQL> declare
  2     ltime integer;
  3  begin
  4     ltime := dbms_utility.get_time;
  5
  6     insert into t select * from s;
  7
  8     ltime := dbms_utility.get_time - ltime;
  9
10     dbms_output.put_line('Exec Time:'||ltime/100||' Seconds...');
11
12     commit;
13  end;
14  /
Exec Time:3.26 Seconds...
PL/SQL procedure successfully completed.Thanks,
Karthick.