How to join PLSQL nested table with normal tables ?

Question

my requirement is to delete the rows in a normal oracle table in one statement, based on the values collected in a PL/SQL nested table which is filled by another program.
In the following example, i need to delete the rows in
the table c_journals where the columns branch_code and
id are having values which exist in the PL/SQL
nested table's columns a and b respectively
declare
type test_type IS RECORD (a VARCHAR2(20), b number(20));
type test_table is table of test_type index by binary_integer;
test_object test_table;
cnt number;
begin
test_object(1).a := '1000';
test_object(1).b := 1;
test_object(2).a := '1006';
test_object(2).b := 4;
/* to be completed */
delete c_journals where ....
end;
Is this possible in Oracle ? Iam using the version 9iR2
Thanks in advance

Answer 1

Both of the following delete statements should work. For the second the two types need to be created as database objects.
declare
  type test_type IS RECORD (a VARCHAR2(20), b number(20));
  type test_table is table of test_type index by binary_integer;
  test_object test_table;  -- := test_table(test_type('1000',1), test_type('1006',4));
  cnt number;
begin
  test_object(1).a := '1000';
  test_object(1).b := 1;
  test_object(2).a := '1006';
  test_object(2).b := 4;
  for i in test_object.first .. test_object.last loop
    delete from c_journals cj
    where test_object(i).a = cj.branch_code
     and test_object(i).b = cj.id;
  end loop;
end;
create or replace type test_type IS object (a VARCHAR2(20), b number(20));
create or replace type test_table is table of test_type;
declare
  test_object test_table := test_table(test_type('1000',1), test_type('1006',4));
  cnt number;
begin
  delete from c_journals cj
  where exists (select 'x' from table(cast(test_object as test_table)) t
     where cj.branch_code = t.a and cj.id = t.b);
end;
/