How to Make a New Phone Number Entry in Address Book?

Question

Can't for the life of me figure out how to do this via AppleScript. I want to create a new contact in Apple's Address Book, and populate the fields with some data. Here's what I have so far (keeping things simple):
set theLastName to "Doe"
set theFirstName to "John"
--etc.
set mobilePhone to "[phone]"
set workPhone to "[phone]"
set homePhone to "[phone]"
tell application "Address Book"
set thisPerson to (make new person with properties {first name: theFirstName, last name:theLastName, organization:"Test Company"})
set the value of phone 1 of person id thisPerson to workPhone
--error
end tell
The new contact record is created properly with first name, last name, and organization/company, but I can't get the phone data in via AppleScript. Does anyone know how to do this?
Any help greatly appreceated.

Answer 1

Hi William,
You need to add the phone entries to the end of the list of phones. Something like this:
tell thisPerson to make new phone at the end of phones with properties {value:"[phone]", label:"home"}
You could also put the telephone numbers into an array in case you don't want to add all the types to all of your entries. Like this:
set theLastName to "Doe"
set theFirstName to "John"
--etc.
set thePhones to {{"[phone]", "home"}, {"[phone]", "work"}, {"[phone]", "mobile"}}
tell application "Address Book"
set thisPerson to (make new person with properties {first name:theFirstName, last name:theLastName, organization:"Test Company"})
repeat with myPhone in thePhones
tell thisPerson to make new phone at the end of phones with properties {value:(item 1 of myPhone), label:(item 2 of myPhone)}
end repeat
save addressbook -- to update Address Book
end tell
Best wishes
John M