How to pass an array to a procedure & how to use array in IN clause in SQL

Question

Hi all,
how do i pass an array of varchar2[10] in an procedure and i want to use this array in the IN caluse of the SQL statement inside the procedure. Can anyone please help me on this.
Thanks & regards
shyam~

Answer 1

There are multiple ways. For example:
SQL> create or replace
  2    type str10_tbl_type is table of varchar2(10)
  3  /
Type created.
SQL> -- Using TABLE operator
SQL> create or replace
  2    procedure p1(
  3                 p_str10_tbl str10_tbl_type
  4                )
  5      is
  6      begin
  7          for rec in (
  8                      select  ename,
  9                              sal
10                        from  emp,
11                              table(p_str10_tbl)
12                        where ename = column_value
13                     ) loop
14            dbms_output.put_line(rpad(rec.ename,10) || rec.sal);
15          end loop;
16  end;
17  /
Procedure created.
SQL> set serveroutput on format wrapped
SQL> exec p1(str10_tbl_type('KING','ALLEN','SMITH'));
KING      5000
ALLEN     1600
SMITH     800
PL/SQL procedure successfully completed.
SQL> -- Using MEMBER OF method
SQL> create or replace
  2    procedure p1(
  3                 p_str10_tbl str10_tbl_type
  4                )
  5      is
  6      begin
  7          for rec in (
  8                      select  ename,
  9                              sal
10                        from  emp
11                        where ename member of p_str10_tbl
12                     ) loop
13            dbms_output.put_line(rpad(rec.ename,10) || rec.sal);
14          end loop;
15  end;
16  /
Procedure created.
SQL> set serveroutput on format wrapped
SQL> exec p1(str10_tbl_type('KING','ALLEN','SMITH'));
SMITH     800
ALLEN     1600
KING      5000
PL/SQL procedure successfully completed.
SQL> SY.