How to put list items in a numbers collumn? HelpxD

Question

Hey guys,
I have made a list of extracted finance.yahoo data containing all the numbers on a balance sheet in applescript and i want to put it in numbers cells
What i need to do now is to
set value of cell E2 tp item 1 of list2010
set value of cell E3 to item 2 of list2010
Could you please help me how to do this task faster?
it is has to go to E38xD
and also i have tried this
A=1
A + 1
A
A is still 1?
how do i add one to A and make it a permanent change to A?
It is to loop like this
A = 2
B = 1
repeat 38 times
set value of cell E"A" to item B of list2010
A + 1
B + 1
but that didn't work:(
thank you so much for helping a noob out

Answer 1

Here is the end of your script with some comments :
--{code}
set list2010 to {cash2010, shortterm2010, netreceivables2010, inventory2010, otherassets2010, totalassets2010, longterminvest2010, propertyplant2010, goodwill2010, intangible2010, amortization2010, otherassets2010, deferredlongterm2010, allasset2010, accountspay2010, shortcurrentdebt2010, othercurrentliabilities2010, totalcurrentliabilities2010, longtermdebt2010, otherliabilities2010, dltlc2010, minorityinterest2010, negativegoodwill2010, totalliabilities2010, miscstock2010, redeemablestock2010, preferred2010, commonstock2010, retainedearnings2010, treasurystock2010, capitalsurplus2010, otherstockholder2010, totalstockholder2010, nettangibleassets2010}
tell application "Numbers"
  activate
          set truedoc to name of front document
          set truesheet to name of first sheet of document truedoc
          set truetable to name of fifth table of sheet truesheet of document truedoc
end tell -- you missed it
tell application "Numbers" to tell document truedoc to tell sheet truesheet to tell table truetable
          set rowscount to row count
          set BE to 2
          set AE to 1
          set myrange to cells of range "E2:E39" (* useless *)
          repeat 38 times
set value of cell E+"BE" to item AE
three errors here :
you failed to enclose E in quotes,
you can’t add a number to a letter
you didn't say where the script must pick the element *)
                    set value of cell ("E" & BE) to item AE of list2010
I dislike this kind of reference. I would use
set value of cell BE of column 5 to item AE of list2010
                    set BE to BE + 1
                    set AE to AE + 1
          end repeat
end tell -- Numbers…
--{code}
It use standard AppleScript but it's not really efficient.
This one would be faster
--{code}
set list2010 to {cash2010, shortterm2010, netreceivables2010, inventory2010, otherassets2010, totalassets2010, longterminvest2010, propertyplant2010, goodwill2010, intangible2010, amortization2010, otherassets2010, deferredlongterm2010, allasset2010, accountspay2010, shortcurrentdebt2010, othercurrentliabilities2010, totalcurrentliabilities2010, longtermdebt2010, otherliabilities2010, dltlc2010, minorityinterest2010, negativegoodwill2010, totalliabilities2010, miscstock2010, redeemablestock2010, preferred2010, commonstock2010, retainedearnings2010, treasurystock2010, capitalsurplus2010, otherstockholder2010, totalstockholder2010, nettangibleassets2010}
Convert the list in a text with a return between values then pass it to the clipboard *)
set the clipboard to my recolle(list2010, return)
tell application "Numbers"
  activate
          set truedoc to name of front document
          set truesheet to name of first sheet of document truedoc
          set truetable to name of fifth table of sheet truesheet of document truedoc
end tell -- you missed it
tell application "Numbers" to tell document truedoc to tell sheet truesheet to tell table truetable
          set selection range to range "E2"
          my pasteMatchingStyle("Numbers")
end tell -- Numbers…
--=====
on recolle(l, d)
          local oTIDs, t
          set oTIDs to AppleScript's text item delimiters
          set AppleScript's text item delimiters to d
          set t to l as text
          set AppleScript's text item delimiters to oTIDs
          return t
end recolle
--=====
on pasteMatchingStyle(theApp)
  activate theApp
          tell application "System Events" to tell application process theApp
                    set frontmost to true
  keystroke "v" using {command down, shift down, option down}
          end tell
end pasteMatchingStyle
--=====
--{code}
Here is a way to reach the wanted table.
Here I assume that it's the only one whose cell A1 contains 2010.
--{code}
tell application "Numbers"
  activate
          set truedoc to name of front document
          tell document truedoc
                    set truesheet to name of first sheet
                    tell sheet truesheet
                              set truetable to ""
                              repeat with t from 1 to count tables
                                        if value of cell "A1" of table t is "2010" then
                                                  set truetable to name of table t
                                                  exit repeat
                                        end if
                              end repeat
                              if truetable is "" then error "The wanted table is unavailable !"
                              tell table truetable
                                        set selection range to range "E2"
                                        my pasteMatchingStyle("Numbers")
                              end tell -- table
                    end tell -- sheet
          end tell -- document
end tell -- Numbers
--=====
--{code}
Yvan KOENIG (VALLAURIS, France) dimanche 18 décembre 2011 18:45:00
iMac 21”5, i7, 2.8 GHz, 12 Gbytes, 1 Tbytes, mac OS X 10.6.8 and 10.7.2
My iDisk is : <http://public.me.com/koenigyvan>
Please : Search for questions similar to your own before submitting them to the community