How to tell Terminal to Do Script in specified Custom Titled window

Question

I'm writing a script that needs to create and name multiple terminal windows. And later in the script revisit those windows and do an individual script in each one.
Here's a very simplified version of the script to show what I'm trying to do. This should Create 2 new terminal windows called "Name_1" and "Name_2." Then later in the script revisit them and run individual scripts "Blah_1" and "Blah_2" in the appropriate windows. But I'm getting an error when I try to call up a window by it's custom name.
And yes, I'm aware that "Blah_1" doesn't achieve anything. It's just a placeholder until I get the actual script written.
set winNumVar to 1
repeat 2 times
          set winTitleVar to "Name_" & winNumVar
          tell application "Terminal"
                    set newWindow to do script -- create a new window with no initial command
                    set title displays custom title of newWindow to true
                    set custom title of newWindow to winTitleVar
          end tell
          set winNumVar to winNumVar + 1
end repeat
set winNumVar to 1
repeat 2 times
          set winTitleVar to "Name_" & winNumVar
          tell application "Terminal"
                do script "Blah_" & winNumVar in window winTitleVar --THIS CREATES THE ERROR
          end tell
          set winNumVar to winNumVar + 1
end repeat

Answer 1

Terminal windows have different properties than tabs, and the name/title can also be modified depending on the preferences.  When you create a new window, a new tab will be created in it - the custom title property of the tab will affect the name of the window.  Depending on your other settings, something like the following should work:
set winNumVar to 1
repeat 2 times
  set winTitleVar to "Name_" & winNumVar
  tell application "Terminal"
    tell first item of (get windows whose name contains winTitleVar) -- get first matching window
      do script "echo this is window " & winNumVar in it
    end tell
  end tell
  set winNumVar to winNumVar + 1
end repeat