How to write report output into table

Question

Hi,
I want to get data out from report "RSPARAM" which list all system profile parameters my requirement is that i need to write output of this report to table so can anyone please tell me how should achieve this?
is there any FM which read report as parameters and write into table?
thanks in advance.
john.

Answer 1

Looks like the program you are calling(rsparam) is just calling another report, RSPFPAR.  Let's just call that one directly.  Here is an updated version of the program.
This will also put the first 3 columns in a internal table.  This should show you what you need to do.
report zrich_0003 .
data: begin of listout occurs 0,
      line(1024) type c,
      end of listout.
data: begin of itab occurs 0,
      column1(100) type c,
      column2(100) type c,
      column3(100) type c,
      therest(100) type c,
      end of itab.
* Submit the report and export list to memory
submit  rspfpar exporting list to memory
            and return.
* Get list from memory and convert to ascii
perform retrieve_list_from_memory tables listout.
loop at listout.
  if sy-tabix => 7.
    clear itab.
split listout+1(500) at '|' into itab-column1 itab-column2
                                 itab-column3 itab-therest.
    append itab.
  endif.
endloop.
loop at itab.
  write:/ itab-column1, itab-column2, itab-column3.
endloop.
* RETRIEVE_LIST_FROM_MEMORY
form retrieve_list_from_memory tables reportlines.
  data: list like abaplist occurs 0 with header line.
  data: txtlines(1024) type c occurs 0 with header line.
  clear list.  refresh list.
  clear reportlines. refresh reportlines.
  call function 'LIST_FROM_MEMORY'
       tables
            listobject = list
       exceptions
            not_found  = 1
            others     = 2.
  check sy-subrc = 0.
  call function 'LIST_TO_ASCI'
       tables
            listobject         = list
            listasci           = txtlines
       exceptions
            empty_list         = 1
            list_index_invalid = 2
            others             = 3.
  check sy-subrc = 0.
  reportlines[] = txtlines[].
  call function 'LIST_FREE_MEMORY'.
endform.
Regards,
Rich Heilman