How to write xml doc to file in PL/SQL

Question

I have a function defined that uses xmlgen.getxml to generate an xml confirmation document. I am calling this function from a trigger and would like to have the returned xml document (a clob) written to an OS file. Can anyone help me with this issue?
Thanks,
John

Answer 1

declare
TYPE weak_cursor_type is REF CURSOR;
curOUT weak_cursor_type;
vOUT clob;
begin
open curOUT FOR SELECT xmlgen.getXML('select * from all_users',1) XML_TXT FROM DUAL;
fetch curOUT into vOUT;
sp_gen_util.output_clob(vOUT,80,'file');
sp_gen_util.output_str(vOUT, 250, 'screen');
end;
----part of package sp_gen_util----
------------- package variables --------------
SUBTYPE max_str_type is varchar2(32767);
wk_CR char:=chr(10);
MAX_STR_LEN constant number:= 32767;
--- driver routine. calls "open_file_function"
--- and "LOBPrint"
--- assumptions: that UTL_DIR has been set in INIT.ORA
--- to support any directories passed
--- inputs: CLOB for output
--- line_length (only affects screen output just now)
--- destination (currently allows "screen" and "file")
--- file_status ("a" append, "w" open for write)
--- dirname (directory path for file)
--- filename (file name for write or append)
PROCEDURE output_clob (
p_str clob,
p_line_length number DEFAULT 80,
p_destination varchar2 DEFAULT 'screen',
p_status varchar2 DEFAULT 'a',
p_dirname varchar2 DEFAULT '/tmp',
p_filename varchar2 DEFAULT 'write_host_file.log' ) IS
v_outfile utl_file.file_type;
begin
wk_substr_len:=p_line_length;
if p_destination='file' then
v_outfile := open_file_fun(p_status, p_dirname, p_filename);
end if;
LOBPrint(p_str,p_destination,v_outfile);
if p_destination='file' then
utl_file.fclose(v_outfile);
end if;
end output_clob;
--- loops through blocks of text by delimiter (carriage return)
--- and writes to either the screen or file
--- (output to screen needs work for clob...currently using
--- "output_str" instead for <32k strings instead)
--- inputs: CLOB for output
--- destination (currently allows "screen" and "file")
--- filehandle (open filehandle from openfile routine)
PROCEDURE LOBPrint(
p_str clob,
p_destination varchar2,
v_outfile utl_file.file_type default null ) is
---------------local working variables
wk_str max_str_type; --MAX=32767
wk_offset INTEGER := 1;
wk_clob clob;
wk_clob_len number;
wk_clob_len2 number;
wk_max_loops number:=70000;
begin
wk_clob_len:= dbms_lob.getlength(p_str);
if wk_clob_len <= MAX_STR_LEN
and p_destination='file' then
--- NOTE: dbms_lob.substr parameters are OPPOSITE of sql substr
utl_file.put_line(v_outfile, dbms_lob.substr( p_str, wk_clob_len, 1));
elsif wk_clob_len > MAX_STR_LEN then
dbms_lob.createtemporary(wk_clob, TRUE, dbms_lob.call);
--- wk_clob: LOB locator of the copy target.
--- p_str: LOB locator of source for the copy.
--- wk_clob_len: Number of bytes (for BLOBs) or characters (for CLOBs)
--- to copy.
--- 1: Offset in bytes or characters in the destination LOB
--- (origin: 1) for the start of the copy.
--- 1: Offset in bytes or characters in the source LOB
--- (origin: 1) for the start of the copy.
dbms_lob.copy(wk_clob, p_str, wk_clob_len, 1, 1);
LOOP
wk_str:=word_parse_trim_lob_FUN(wk_clob,wk_CR);
if p_destination='file' then
utl_file.put_line(v_outfile, wk_str);
elsif p_destination='screen' then
dbms_output.put_line(wk_str);
end if;
wk_clob_len2:= dbms_lob.getlength(wk_clob);
EXIT WHEN wk_clob is null ;
END LOOP;
end if;
END LOBPrint;
--- "function with side-effect"
--- input is CLOB, with is "returned" without leading field
--- additional parameter is field (or token) delimiter
--- value returned is leading field from input string
FUNCTION word_parse_trim_lob_FUN(o_str IN OUT NOCOPY clob,
p_delimiter IN varchar2) RETURN varchar2
IS
o_token max_str_type;
clob_len number;
next_pos number;
wk_clob clob;
BEGIN
clob_len:= dbms_lob.getlength(o_str);
next_pos:= dbms_lob.instr(o_str, p_delimiter, 1, 1);
if next_pos != 0 then
-- NOTE: dbms_lob.substr parameters are OPPOSITE of sql substr
dbms_lob.createtemporary(wk_clob, TRUE, dbms_lob.call);
o_token:= dbms_lob.substr( o_str, next_pos-1, 1);
-- o_str:= dbms_lob.substr(o_str,clob_len-next_pos,next_pos+1);
if next_pos = clob_len then
wk_clob := null;
else
--- wk_clob: LOB locator of the copy target.
--- o_str: LOB locator of source for the copy.
--- clob_len: Number of bytes (for BLOBs) or characters (for CLOBs)
--- to copy.
--- 1: Offset in bytes or characters in the destination LOB
--- (origin: 1) for the start of the copy.
--- next_pos+1: Offset in bytes or characters in the source LOB
--- (origin: 1) for the start of the copy.
dbms_lob.copy(wk_clob, o_str, clob_len, 1, next_pos+1);
end if;
else
o_token:= dbms_lob.substr( o_str, MAX_STR_LEN, 1);
end if;
o_str := wk_clob;
RETURN(o_token);
EXCEPTION
when others then
null;
-- dbms_output.put_line('Error:'||SQLCODE||',text:'||SQLERRM);
END word_parse_trim_lob_FUN;