I want to make performance fast of this query.

Question

Hello friends,
I have used following queries in my 9 screen interactive report.Output/result is perfect but performance became damn slow.
I have used........(note : T2 is internal table)
SELECT VBELN INTO (T2-VBELN) FROM VBAK WHERE
AUART IN AUART AND  VBELN IN VBELN.
SELECT  NETWR POSNR INTO (T2-NETWR,T2-POSNR) FROM VBAP
WHERE  VBELN = T2-VBELN .
  SELECT AUFNR KDPOS PSMNG WEMNG INTO (T2-AUFNR,T2-KDPOS,T2-PSMNG,  T2-WEMNG) FROM AFPO WHERE KDAUF =  T2-VBELN .
    SELECT  DMBTR MATNR MENGE ELIKZ INTO (T2-DMBTR,T2-MATNR,T2-MENGE,T2-ELIKZ) FROM AUFM WHERE AUFNR = T2-AUFNR AND ELIKZ <> 'X'.
    SELECT SINGLE MAKTX INTO (T2-MAKTX) FROM MAKT
    WHERE MATNR = T2-MATNR.
      APPEND T2.
    ENDSELECT.
  ENDSELECT.
ENDSELECT.
ENDSELECT.
Please sujjest me the any other option for this query.
Thanks in advance.
Regards,
n.i.m.z.

Answer 1

Hi,
Please have a look at this code and see if it helps you. You will have to test this code properly as I could not do that due to the fact that I do not have any relevant data on my system. Please let me know if this helps you and do not forget to reward points if this was helpful.
TABLES: vbak.
SELECT-OPTIONS: vbeln FOR vbak-vbeln,
                auart FOR vbak-auart.
DATA: BEGIN OF t2 OCCURS 0,
        vbeln TYPE vbak-vbeln,
        posnr TYPE vbap-posnr,
        netwr TYPE vbap-netwr,
        aufnr TYPE afpo-aufnr,
        kdpos TYPE afpo-kdpos,
        psmng TYPE afpo-psmng,
        wemng TYPE afpo-wemng,
        dmbtr TYPE aufm-dmbtr,
        matnr TYPE aufm-matnr,
        menge TYPE aufm-menge,
        elikz TYPE aufm-elikz,
        maktx TYPE makt-maktx,
      END OF t2,
      BEGIN OF t_vbak OCCURS 0,
        vbeln TYPE vbak-vbeln,
      END OF t_vbak,
      BEGIN OF t_vbap OCCURS 0,
        vbeln TYPE vbap-vbeln,
        posnr TYPE vbap-posnr,
        netwr TYPE vbap-netwr,
      END OF t_vbap,
      BEGIN OF t_afpo OCCURS 0,
        kdauf TYPE afpo-kdauf,
        kdpos TYPE afpo-kdpos,
        aufnr TYPE afpo-aufnr,
        posnr TYPE afpo-posnr,
        psmng TYPE afpo-psmng,
        wemng TYPE afpo-wemng,
      END OF t_afpo,
      BEGIN OF t_aufm OCCURS 0,
        aufnr TYPE aufm-aufnr,
        mblnr TYPE aufm-mblnr,
        mjahr TYPE aufm-mjahr,
        zeile TYPE aufm-zeile,
        dmbtr TYPE aufm-dmbtr,
        matnr TYPE aufm-matnr,
        menge TYPE aufm-menge,
        elikz TYPE aufm-elikz,
      END OF t_aufm,
      BEGIN OF t_makt OCCURS 0,
        matnr TYPE makt-matnr,
        maktx TYPE makt-maktx,
      END OF t_makt,
      t_afpo_tmp LIKE TABLE OF t_afpo,
      t_aufm_tmp LIKE TABLE OF t_aufm.
REFRESH t2.
SELECT vbeln
  FROM vbak
  INTO TABLE t_vbak
  WHERE vbeln IN vbeln
  AND   auart IN auart.
IF sy-subrc EQ 0.
  SORT t_vbak BY vbeln.
  SELECT vbeln
         posnr
         netwr
    FROM vbap
    INTO TABLE t_vbap
    FOR ALL ENTRIES IN t_vbak
    WHERE vbeln EQ t_vbak-vbeln.
  IF sy-subrc EQ 0.
    SORT t_vbap BY vbeln
                   posnr.
    SELECT kdauf
           kdpos
           aufnr
           posnr
           psmng
           wemng
      FROM afpo
      INTO TABLE t_afpo
      FOR ALL ENTRIES IN t_vbap
      WHERE kdauf EQ t_vbap-vbeln
      AND   kdpos EQ t_vbap-posnr.
    IF sy-subrc EQ 0.
      SORT t_afpo BY kdauf
                     kdpos.
      t_afpo_tmp[] = t_afpo[].
      SORT t_afpo_tmp BY aufnr.
      DELETE ADJACENT DUPLICATES FROM t_afpo_tmp COMPARING aufnr.
      SELECT aufnr
             mblnr
             mjahr
             zeile
             dmbtr
             matnr
             menge
             elikz
        FROM aufm
        INTO TABLE t_aufm
        FOR ALL ENTRIES IN t_afpo_tmp
        WHERE aufnr EQ t_afpo_tmp-aufnr.
      IF sy-subrc EQ 0.
        DELETE t_aufm WHERE elikz EQ 'X'.
        SORT t_aufm BY aufnr.
        IF NOT t_aufm[] IS INITIAL.
          t_aufm_tmp[] = t_aufm[].
          SORT t_aufm_tmp[] BY matnr.
          DELETE ADJACENT DUPLICATES FROM t_aufm_tmp COMPARING matnr.
          SELECT matnr
                 maktx
            FROM makt
            INTO TABLE t_makt
            FOR ALL ENTRIES IN t_aufm_tmp
            WHERE matnr EQ t_aufm_tmp-matnr
            AND   spras EQ sy-langu.
          IF sy-subrc EQ 0.
            SORT t_makt BY matnr.
          ENDIF.
        ENDIF.
      ENDIF.
    ENDIF.
  ENDIF.
ENDIF.
IF t_makt[] IS INITIAL.
  MESSAGE e208(00) WITH 'No records found'.
ELSE.
  LOOP AT t_vbap.
    READ TABLE t_afpo WITH KEY kdauf = t_vbap-vbeln
                               kdpos = t_vbap-posnr
                               BINARY SEARCH
                               TRANSPORTING
                                 kdpos
                                 aufnr
                                 psmng
                                 wemng.
    IF sy-subrc EQ 0.
      READ TABLE t_aufm WITH KEY aufnr = t_afpo-aufnr
                                 BINARY SEARCH
                                 TRANSPORTING
                                   dmbtr
                                   matnr
                                   menge
                                   elikz.
      IF sy-subrc EQ 0.
        READ TABLE t_makt WITH KEY matnr = t_aufm-matnr
                                   BINARY SEARCH
                                   TRANSPORTING
                                     maktx.
        IF sy-subrc EQ 0.
          t2-vbeln = t_vbap-vbeln.
          t2-posnr = t_vbap-posnr.
          t2-netwr = t_vbap-netwr.
          t2-aufnr = t_afpo-aufnr.
          t2-kdpos = t_afpo-kdpos.
          t2-psmng = t_afpo-psmng.
          t2-wemng = t_afpo-wemng.
          t2-dmbtr = t_aufm-dmbtr.
          t2-matnr = t_aufm-matnr.
          t2-menge = t_aufm-menge.
          t2-elikz = t_aufm-elikz.
          t2-maktx = t_makt-maktx.
          APPEND t2.
          CLEAR  t2.
        ENDIF.
      ENDIF.
    ENDIF.
  ENDLOOP.
ENDIF.
Regards,
Mark