INNER JOIN Where to Use

Question

hi,
is there any criteria determining the usage of <b>inner join</b>, i.e no. of rows to be retrieved from the tables... can we avoid using <b>inner joins</b>...
i hope i have cleared my query.....
thanx in advance
abhishek suppal

Answer 1

Abhishek,
Inner joins (when used correctly) are a GOOD thing.
The criteria as to when to use an inner join is that the tables must have common values. For example let's look at VBAK and VBAP. The both share VBELN as their common link. And becasue VBELN is part of their keys it is very good to use an inner join if you need data from both tables.
eg. We want to get sales Order data into TBL_SALESORDER from VBAK / VBAP
Without Inner Join you can do it something like this:
data: begin of tbl_vbak occurs 0,
        vbeln  like vbak-vbeln,
        kunnr  like vbak-kunnr,
        audat  like vbak-audat,
      end of tbl_vbak.
data: begin of tbl_vbap occurs 0,
        vbeln  like vbap-vbeln,
        posnr  like vbap-posnr,
        matnr  like vbap-matnr,
        zmeng  like vbap-zmeng,
      end of tbl_vbap.
data: begin of tbl_salesorder occurs 0,
        vbeln  like vbak-vbeln,
        kunnr  like vbak-kunnr,
        audat  like vbak-audat,
        posnr  like vbap-posnr,
        matnr  like vbap-matnr,
        zmeng  like vbap-zmeng,
      end of tbl_salesorder.
data: l_index like st-tabix.
select vbeln kunnr audat
       into table tbl_vbak
       from vbak.
check sy-subrc eq 0.
select vbeln posnr matnr zmeng
       into table tbl_vbap
       from vbap
       for all entries in tbl_vbak
       where vbeln = tbl_vbak-vbeln.
check sy-subrc eq 0.
sort tbl_vbap by vbeln posnr.
loop at tbl_vbak.
  read table tbl_vbap with key vbeln = tbl_vbak-vbeln
                               binary search.
  if sy-subrc eq 0.
    l_index = sy-tabix.
    loop at tbl_vbap from l_index.
      if tbl_vbak-vbeln ne tbl_vbap-vbeln.
        exit.
      endif.
      clear tbl_salesorder.
      move-corresponding tbl_vbak to tbl_salesorder.
      move-corresponding tbl_vbap to tbl_salesorder.
      append tbl_salesorder.
    endloop.
  endif.
endloop.
With an inner join you can do it like this:
data: begin of tbl_salesorder occurs 0,
        vbeln  like vbak-vbeln,
        kunnr  like vbak-kunnr,
        audat  like vbak-audat,
        posnr  like vbap-posnr,
        matnr  like vbap-matnr,
        zmeng  like vbap-zmeng,
      end of tbl_salesorder.
select vbak~vbeln vbak~kunnr vbak~audat
       vbap~posnr vbap~matnr vbap~zmeng
       into table tbl_salesorder
       from vbak
       inner join vbap
       on vbak~vbeln = vbap~vbeln.
In the above example it is more efficient to use the inner join because we hit the database once. Without the inner join we hit the database twice (once for the VBAK info and the other time for the VBAP info).
If you want to restrict the data you canuse a select option or parameter like any other SELECT statement. What you probably would not do is use the "UP TO X ROWS" clause as this will essentially limit the data from VBAP not VBAK.
I know that this example is a very simple one and we were luck to be able to "join" the tables using their primary keys. If the "join" between the tables are not by their primary keys or by an index then you may need to reconsider using an inner join and this will cause performance problems.
I hope this makes some sense. Let me know if you need more info, alternatively take a look at the SAP Help (F1) for SELECT.
Cheers,
Pat.
PS. Kindly assign Reward Points to the posts you find helpful.