Insert Handlers

Question

Hi,
I have a requirement from my clients to handle the following event :
If an insert fails due to a primary key conflict (ORA-00001) then switch the INSERT to an UPDATE and re-apply. I have got most of the logic in place but it fails due to the lack of the old data. I have tried using the new data as the old data as well but it still throws a 01403 at me.
The handler has to be generic as there are literally hundreds of tables as well.
Any suggestions are appreciated.

Answer 1

Okay - got this working - requires a few things :
One - the handlers itself :
create or replace PACKAGE BODY "INSERT_ERRORS_PKG" AS
PROCEDURE insert_lcr (
   message IN SYS.ANYDATA,
   error_stack_depth IN NUMBER,
   error_numbers IN DBMS_UTILITY.NUMBER_ARRAY,
   error_messages IN EMSG_ARRAY )
  IS
    any_data    SYS.ANYDATA;
    lcr         SYS.LCR$_ROW_RECORD;
    retValue    PLS_INTEGER;
    apply_name  VARCHAR2(30);
    errlog_rec  tex_error_log%ROWTYPE ;
    newvals    SYS.LCR$_ROW_LIST;
    oldvals    SYS.LCR$_ROW_LIST;
    colname    VARCHAR2(255);
    coldata    SYS.ANYDATA;
    isPK       NUMBER;
  BEGIN
   -- If we have a uniqueness constraint (2290,1) or mismatch/missing (1403) or DDL mismatch on nullable (1400, 1401)
    IF error_numbers(1) IN ( 2290, 1 ) THEN
     any_data := DBMS_STREAMS.GET_INFORMATION('CONSTRAINT_NAME');
     retValue := any_data.GetVarchar2(errlog_rec.text);
       errlog_rec.resolution := 'UPDATE';
    ELSIF error_numbers(1) IN (1400, 1401) THEN
     errlog_rec.resolution := 'SCHEMA_INS';
    ELSE
     errlog_rec.text := NULL ;
     errlog_rec.resolution := 'UPDATE';
    END IF ;
    -- Get the name of the sender and the name of the apply process
    any_data       := DBMS_STREAMS.GET_INFORMATION('SENDER');
    retValue       := any_data.GETVARCHAR2(errlog_rec.sender);
    apply_name     := DBMS_STREAMS.GET_STREAMS_NAME();
    -- access the LCR and set the logging records
    retValue := message.GETOBJECT(lcr);
    errlog_rec.object_name := lcr.GET_OBJECT_NAME() ;
    errlog_rec.command_type := lcr.GET_COMMAND_TYPE() ;
    errlog_rec.errnum := error_numbers(1) ;
    errlog_rec.errmsg := error_messages(1) ;
    IF error_numbers(1) NOT IN (1, 1400, 1401) THEN
      errlog_rec.text := 'Reapplied as UPDATE' ;
    ELSE
      IF error_numbers(1) IN (1) THEN
        errlog_rec.text := 'Forced UPDATE' ;
      ELSE
        errlog_rec.text := 'Record DROPPED' ;
      END IF;
    END IF;
    -- now update the logging table
    INSERT INTO buftex.tex_error_log
    (error_date,object_name,apply_name,sender,command_type,resolution,errnum,errmsg,text,lcr, lcr_old)
    VALUES (
      SYSDATE,
      errlog_rec.object_name,
      apply_name,
      errlog_rec.sender,
      errlog_rec.command_type,
      errlog_rec.resolution,
      errlog_rec.errnum,
      errlog_rec.errmsg,
      errlog_rec.text,
      lcr.GET_VALUES('new', 'n'),
      lcr.GET_VALUES('old')
   commit;
    -- If we don't have a unique field violation then proceed
    IF error_numbers(1) NOT IN (1400, 1401) THEN
      -- added
      newvals := lcr.GET_VALUES('new', 'y');
      oldvals := lcr.GET_VALUES('new', 'y');
      --lcr.GET_SOURCE_DATABASE_NAME(),
      construct_row_lcr(
        source_dbname  =>  lcr.GET_SOURCE_DATABASE_NAME(),
        cmd_type       =>  'UPDATE',
        obj_owner      =>  lcr.GET_OBJECT_OWNER(),
        obj_name       =>  errlog_rec.object_name,
        old_vals       =>  oldvals,
        new_vals       =>  newvals,
        apply_name     =>  apply_name);
    END IF;
  END insert_lcr ;
END insert_errors_pkg;
/Then, you MUST set the following up for the tables to avoid errors :
DECLARE
  sqltext varchar2(3000);
CURSOR tbl_cur IS
SELECT table_name
  FROM all_tables
  WHERE owner = 'OWNER'
  and table_name like ('%');
BEGIN
  FOR x IN tbl_cur
  LOOP
   sqltext := 'DECLARE cols DBMS_UTILITY.NAME_ARRAY; BEGIN cols(1) := ''MODIFY_DATE''; DBMS_APPLY_ADM.SET_UPDATE_CONFLICT_HANDLER(object_name => ''BUFTEX.' || x.table_name || ''',method_name => ''OVERWRITE'',  resolution_column => ''MODIFY_DATE'', column_list => cols); END;';
   execute immediate sqltext;
  END LOOP;
END;
/Presto - test by setting the TAG to something other then NULL, insert a record in the target. Go to the source, make sure the TAG is NULL and insert the same record - you get a nice error message in the error table and the record in the target is updated.
Have fun
John