IPhoto '11 can't export

Question

Recently I've been having a couple problems using iPhoto '11, version 9.1.3 (607).
I am routinely taking photos (JPG) and putting them into iPhoto. I'm right-clicking in iPhoto and knocking out backgrounds in Photoshop CS3 (my default external editor). I'm then copying that file, now a .psd file, back into iPhoto. Here's where the problem starts. Now I want to edit the psd file so I right-click on the file and click on "edit in external editor". It switches over to Photoshop and get an error that reads "Could not complete your request because an unknown or invalid JPEG marker type is found".
I'm also having a problem exporting some files with iPhoto giving an error that it can't create the file on the volume. I've tried various volumes but it will always give the error. When I take the picture out that it errors-out on, and export again, iPhoto will continue to export until it hits another photo. As far as I can tell there is nothing different about the files that throw up the error.
I'd really like to revert back to my older version of iPhoto. iPhoto '11 has some nice features but it seems a bit buggy.
Thanks, Dan

Answer 1

I have a workaround for the JPEG marker type problem when one is editing TIFF files. The principle should work for other types stored in iPhoto as well. The underlying problem is that iPhoto is renaming your TIFF (or whatever) image as a JPEG - that is, if your image is called "foo.tif" it's making a copy of it called "foo.jpg" but the contents are still in TIFF format. Thus Photoshop gets confused when opening it - it believes it to be a jpeg image but can't read it as such.
My solution is to write a short applescript that invokes Photoshop on the image but tells Photoshop that the image is in fact a tiff image. Then you tell iPhoto that this script is your photo editor (instead of Photoshop).
Here's the script for CS5. (There are reports that CS5 handles the file argument differently from other programs or versions, so if you get a problem there you'd have to adjust the script accordingly). Paste it into the Applescript Editor, save it out as a an application (don't check any of the options in the save dialog), and then go to iPhoto preferences to choose this instead of Photoshop as your image editor. A better script would figure out more thoroughly what kind of file this was and tell Photoshop to open it as such.
on run
          set thefile to choose file with prompt "Choose a file to edit as tiff..."
  openInPs(thefile)
end run
on open filelist
          repeat with thefile in filelist
  openInPs(thefile)
          end repeat
end open
on openInPs(thefile)
          tell application "Finder"
                    set thename to thefile as string -- save away the name in a form CS5 understands
                    set inname to quoted form of (POSIX path of thefile) -- and in a form that Unix shell understands
                    set mycommand to "file " & inname & "| grep -q TIFF" -- shell: grep for the word TIFF in the description of this file
                    try
  do shell script mycommand -- run the shell script.
                              tell application "Adobe Photoshop CS5" -- if the word TIFF was found, open as TIFF
  open alias thename as TIFF
                              end tell
                    on error -- if the word TIFF was not found, we end up here
                              tell application "Adobe Photoshop CS5" -- and just try opening the file with no "as" option
  open alias thename
                              end tell
                    end try
          end tell
end openInPs