Is it possible to export all information (metadata, list of pictures within each album or project) about ALL pictures in Aperture to text files, in a single operation?

Question

I have downloaded a trial version of Aperture because I would like to switch from using Picasa and gimp to using Aperture.  I already know that I want to use Aperture, and that I cannot learn how in 30 days.  I want to use the 30 days to see if I can solve a different problem: bulk export of all information except edits and versions from Aperture.
I want to avoid locking information (other than than the edits and version information that Aperture maintains) about my photos into any one piece of software.
Picasa stores a copy of almost all its information in text filies (mostly XML or .ini format) that are scattered through its picture library.  These files can be scanned and found by use of Mac OS X tools that are availabe in Terminal (at the bash command line).  All of the information about albums, faces, etc can be exported by a single command (after wtiting the progams that the command will initiate.  I have not yest found any similar files in Aperture.
Aperture supports the export of EXIF and IPTC metadata, but only for selected photos, and does not appear to support the export of other information at all.
What I would like to do with a single operation, from either Aperture or Terminal, is to export the entire arrangement of phost ins albums and projects, lists of albums, projects and phots with all metadata (including added keywords) attached to each, and for referenced photos, the external file name.  I do not care if would be in one file or many different text files, because Mac OS X provides all the tools I would need to extract the information I would want from any number of text files.
This would allow me to reconstruct all of the information about my photos (except for edits and versions) outside Aperture, and to use that info in a database outside Aperture.  I would then be able to use Aperture while still being able to do everything that I could do with Picasa.
The most helpful form of an answer to this question might be a list of places to look in the Apple support and Apple developer documentation.  It is difficult to teach me anything complicated, but I am fairly good at figuring out things from documentation.

Answer 1

The following script recursively lists the content of an Aperture library.  The output is simple, for demonstration puposes, but could be modified to XML.  If the XML were that of a PLIST, the Apple Property List viewer oculd be used to diaplsy the output.
A simlar script produces all of the keywords and tags for all of the images in Aperture.
The scripts run much faster in the shell than in the AppleScript Editor bcause the shwll produces no debugging or monitoring information.
#!/usr/bin/env osascript
(*    Demo: list the containment hierarchy in Aperture, starting from libraries.
    Runs from AppleScript Editor, or as a shell command
    References:
        Aperture 3 AppleScript Reference Manual,
            particularly the Containment Diagram in Appendix A
            from the link on "Aperture Resources" web page at http://images.apple.com/aperture/resources/
        Aperture AppleScript Dictionary, accessed from AppleScript Editor
    Ian E. Gorman
global outputFile
set outputFilePath to "/Users/ian/prj/sw/AppleScript/ApertureContainment.txt"
global lineEnd
set lineEnd to "
global tabChar
set tabChar to "    "
on writeText(str)
    write str to outputFile
end writeText
# Open the file, guarantee closure after any error, and list the contents of Aperture libraries
try
    set outputFile to open for access POSIX file outputFilePath with write permission
    set eof outputFile to 0 # truncate the file, if it already exists
    my listAll()
    close access outputFile
on error errorMsg number errNum from offendingObj partial result resutList to expectedType
    try
        display alert "Operation failed, attempting to close output file" & lineEnd & "Error number " & errNum & ": " & errorMsg
        close access outputFile
        display alert "Operation failed, but output file has been closed"
    on error
        display alert "Operation failed, also failed to close output file"
    end try
end try
# top-level in Aperture
on listAll()
    tell application "Aperture"
        repeat with eachLibrary in libraries
            my listLibrary(0, eachLibrary)
        end repeat
    end tell
end listAll
on listLibrary(level, thisLibrary)
    local newLevel
    set newLevel to 1 + (level as integer)
    tell application "Aperture"
        my writeText((newLevel as rich text) & tabChar & "library" & tabChar & (name of thisLibrary) & lineEnd)
        repeat with eachAlbum in albums of thisLibrary
            my listAlbum(newLevel, eachAlbum)
        end repeat
        repeat with eachFolder in folders of thisLibrary
            my listFolder(newLevel, eachFolder)
        end repeat
        repeat with eachProject in projects of thisLibrary
            my listProject(newLevel, eachProject)
        end repeat
        repeat with eachImageVersion in image versions of thisLibrary
            my listImageVersion(newLevel, eachImageVersion)
        end repeat
    end tell
end listLibrary
on listAlbum(level, thisAlbum)
    local newLevel
    set newLevel to 1 + (level as integer)
    tell application "Aperture"
        my writeText((newLevel as rich text) & tabChar & "album" & tabChar & (name of thisAlbum) & lineEnd)
        repeat with eachImageVersion in image versions of thisAlbum
            my listImageVersion(newLevel, eachImageVersion)
        end repeat
    end tell
end listAlbum
on listFolder(level, thisFolder)
    local newLevel
    set newLevel to 1 + (level as integer)
    tell application "Aperture"
        my writeText((newLevel as rich text) & tabChar & "folder" & tabChar & (name of thisFolder) & lineEnd)
        repeat with eachAlbum in albums of thisFolder
            my listAlbum(newLevel, eachAlbum)
        end repeat
        repeat with eachFolder in folders of thisFolder
            my listFolder(newLevel, eachFolder)
        end repeat
        repeat with eachProject in projects of thisFolder
            my listProject(newLevel, eachProject)
        end repeat
        repeat with eachImageVersion in image versions of thisFolder
            my listImageVersion(newLevel, eachImageVersion)
        end repeat
    end tell
end listFolder
on listProject(level, thisProject)
    local newLevel
    set newLevel to 1 + (level as integer)
    tell application "Aperture"
        my writeText((newLevel as rich text) & tabChar & "project" & tabChar & (name of thisProject) & lineEnd)
        repeat with eachAlbum in albums of thisProject
            my listAlbum(newLevel, eachAlbum)
        end repeat
        repeat with eachSubfolder in subfolders of thisProject
            my listSubfolder(newLevel, eachSubfolder)
        end repeat
        repeat with eachImageVersion in image versions of thisProject
            my listImageVersion(newLevel, eachImageVersion)
        end repeat
    end tell
end listProject
on listSubfolder(level, thisSubfolder)
    local newLevel
    set newLevel to 1 + (level as integer)
    tell application "Aperture"
        my writeText((newLevel as rich text) & tabChar & "subfolder" & tabChar & (name of thisSubfolder) & lineEnd)
        repeat with eachAlbum in albums of thisSubfolder
            my listAlbum(newLevel, eachAlbum)
        end repeat
        repeat with eachSubfolder in subfolders of thisSubfolder
            my listSubfolder(newLevel, eachSubfolder)
        end repeat
        repeat with eachImageVersion in image versions of thisSubfolder
            my listImageVersion(newLevel, eachImageVersion)
        end repeat
    end tell
end listSubfolder
on listImageVersion(level, thisImageVersion)
    local newLevel
    set newLevel to 1 + (level as integer)
    tell application "Aperture"
        my writeText((newLevel as rich text) & tabChar & "image version" & tabChar & (name of thisImageVersion) & lineEnd)
    end tell
end listImageVersion