Issue with the select query

Question

Hi,
DATA: BEGIN OF IT_MATERIAL OCCURS 0,
      IDNRK  LIKE  STPO-IDNRK,
      MATNR  LIKE  MAST-MATNR,
      END OF IT_MATERIAL.
FORM CHECK_SALESDATA_EXISTENCE .
  IF NOT IT_MATERIAL[] IS INITIAL.
    LOOP AT IT_MATERIAL.
      CLEAR VBAP.
      SELECT SINGLE * FROM VBAP WHERE MATNR EQ IT_MATERIAL-MATNR.
      IF SY-SUBRC NE 0.
        DELETE IT_MATERIAL WHERE IDNRK EQ IT_MATERIAL-IDNRK
                             AND MATNR EQ IT_MATERIAL-MATNR.
      ENDIF.
      CLEAR IT_MATERIAL.
    ENDLOOP.
  ENDIF.
ENDFORM.                    " CHECK_SALESDATA_EXISTENCE
The above is the subroutine in the program which check whether sales data exists for a material or not. But the problem is the select statement which is written in the loop is taking so much of time because of this the program is going into short dump "Time Exceed Limit".
Please suggest how can i modifiy the above statemnt so that the performance of the program increases.
<REMOVED BY MODERATOR>
Thanks.
Edited by: Alvaro Tejada Galindo on Mar 4, 2008 10:37 AM

Answer 1

The program deletes multiple records inside a loop. This isn't good practice. The following should work:
REPORT ztest LINE-SIZE 80 MESSAGE-ID 00.
TABLES: vapma.
DATA: BEGIN OF it_material OCCURS 0,
  matnr LIKE mast-matnr,
  idnrk LIKE stpo-idnrk,
END OF it_material.
PERFORM check_salesdata_existence.
*&      Form  CHECK_SALESDATA_EXISTENCE
*       text
FORM check_salesdata_existence .
  DATA: delete.
  SORT it_material BY matnr.
  LOOP AT it_material.
    AT NEW matnr.
      SELECT SINGLE * FROM vapma
        WHERE matnr EQ it_material-matnr.
      IF sy-subrc <> 0.
        delete = 'X'.
      ELSE.
        CLEAR delete.
      ENDIF.
    ENDAT.
    IF delete = 'X'.
      DELETE it_material.
    ENDIF.
  ENDLOOP.
ENDFORM. " CHECK_SALESDATA_EXISTENCE
Note that I have changed the filed order in it_material so that AT NEW will work correctly.
Rob