Large numbers! Need help

Question

I have problem. I need to do a multiplication of to large numbers(about 150 digits). But I don't know which way I could do it. Could anyone help me?
Thanx for help.

Answer 1

I can conribute a quick and dirty string multiplication function just to play with:
- does not treat signs
- does not treat decimals
Just to show it can be done
All credits to the yesterday's bad weather - made me think about "old days" (;-o)
CREATE OR REPLACE
function multiply_them(x in varchar2,y in varchar2) return varchar2 is
  retval varchar2(2001) := '0';
  i pls_integer;
  j pls_integer;
  half varchar2(1000);
  dble varchar2(2001);
  z varchar2(1000);
  w varchar2(1000);
function number_is_it(x in varchar2) return boolean is
begin
  if (x = '') or (x is null) then
    return FALSE;
  end if;
  return (replace(translate(x,'0123456789',rpad(chr(9),10,chr(9))),chr(9),'') is null);
end;
function odd_is_it(x in varchar2) return boolean is
begin
  return (mod(to_number(substr(x,-1,1)),2) = 1);
end;
function add_them(x in varchar2,y in varchar2) return varchar2 is
  retval varchar2(1001) := '';
  z varchar2(1000);
  w varchar2(1000);
  i pls_integer;
  j pls_integer;
  carry pls_integer := 0;
begin
  if x is null or y is null then
    return null;
  end if;
  if x = '0' then
    return y;
  end if;
  if y = '0' then
    return x;
  end if;
  i := length(x);  -- TO CALL FUNCTION ONLY ONCE
  j := length(y);
-- FOR NOW WE JUST LEFT PAD THE SHORTER STRING WITH ZEROS TO MAKE THEIR LENGTHS EQUAL
-- IN CASE OF BIG LENGTH DIFFERENCE TO DO:
-- WHEN THE SHORTER STRING IS EXHAUSTED CONCATENATE THE HEAD OF THE LONGER STRING TO PARTIAL SUM OBTAINED
  if i > j then
    z := x;
    w := lpad(y,i,'0');  
  elsif i < j then
    z := lpad(x,j,'0');
    w := y;
    i := j;
  else
    z := x;
    w := y;
  end if;
  while i >= 0 loop
    if i > 0 then
      j := to_number(substr(z,i,1)) + to_number(substr(w,i,1)) + carry;
      carry := trunc(j/10,0);
      retval := to_char(j - 10 * carry) || retval;
    end if;
    i := i - 1;
  end loop;
  return to_char(carry) || retval;
end;
function double_it(x in varchar2) return varchar2 is
  retval varchar2(1001);
begin
  retval := add_them(x,x);
  return ltrim(retval,'0');
end;
function halve_it(x in varchar2) return varchar2 is
  retval varchar2(1000) := '';
  i pls_integer := 1;
  j pls_integer := length(x);
  k number;
  carry pls_integer := 0;
begin
  if x is null then
    return null;
  end if;
  if x = '1' then
    return '0';
  end if;
  if substr(x,1,1) = '1' then
    carry := 10;
    i := 2;
  end if;
  while j >= i loop  
    k := (to_number(substr(x,i,1)) + carry) / 2;
    if k = trunc(k,0) then
      carry := 0;
    else
      carry := 10;
    end if;
    retval := retval || to_char(trunc(k,0));
    i := i + 1;
  end loop;
  return retval;
end;
begin
-- WE WILL DO "PEASANT MULTIPLICATION" (MORE EFFICIENT THAN CONVENTIONAL MULTIPLICATION):
-- WHEN THE FACTOR TO BE HALVED IS ODD WE ADD THE CORRESPONDING DOUBLE TO THE RESULT (INITIALLY ZERO)
-- AT EACH STEP WE HALVE ONE FACTOR AND DOUBLE THE OTHER
-- STEPS ARE REPEATED UNTIL THE HALVED FACTOR IS GREATER THAN ZERO
  if x is null or y is null then
    return null;
  end if;
  if number_is_it(x) and number_is_it(y) then  -- THEY ARE BOTH NUMBERS
-- CHECK FOR TRIVIAL RESULTS: MULTIPLICATION BY ZERO AND MULTIPLICATION BY ONE
    z := ltrim(x,'0');  -- TRIM LEADING ZEROS (JUST IN CASE)
    if z = '' then
      return '0';  -- SINCE ALL ZEROS WERE TRIMMED OFF X IS ZERO
    end if;
    w := ltrim(y,'0');  -- TRIM LEADING ZEROS (JUST IN CASE)
    if w = '' then
      return '0';  -- SINCE ALL ZEROS WERE TRIMMED OFF Y IS ZERO
    end if;
    if z = '1' then
      return w;
    end if;
    if w = '1' then
      return z;
    end if;
    i := length(z);  -- TO CALL FUNCTION ONLY ONCE
    j := length(w);
-- WILL DO IT IN LESS STEPS IF THE LESSER FACTOR GETS HALVED AND THE GREATER FACTOR GETS DOUBLED
    if i > j then  -- X > Y => Y WILL BE HALVED AND X WILL BE DOUBLED
      half := w;
      dble := z; 
    elsif i < j then  -- X < Y => X WILL BE HALVED AND Y WILL BE DOUBLED
      half := z;
      dble := w;
    else  -- X AND Y ARE EQUAL LENGTH STRINGS SO WE COMPARE THE FIRST CHARACTERS
      if substr(z,1,1) <= substr(w,1,1) then  -- X < Y => X WILL BE HALVED AND Y WILL BE DOUBLED
        half := z;
        dble := w;
      else  -- X > Y => Y WILL BE HALVED AND X WILL BE DOUBLED
        half := w;
        dble := z;
      end if; 
    end if;
-- PEASANT MULTIPLICATION
    while half > '0' loop
      if odd_is_it(half) then
        retval := add_them(retval,dble);
      end if;
      half := halve_it(half);
      dble := double_it(dble);
    end loop;
    retval := ltrim(retval,'0');
  else
    retval := 'at least one of the two operands is not a number';
  end if;
  return retval;
end;Regards
Etbin