Move a block of text from one document to another

Question

How to make a script moving a block of text from a defined area to next document?

Answer 1

Here is the beast.
--[SCRIPT exportTextBlocks]
Save the script as a Script, an Application or an Application Bundle: exportTextBlocks.xxx
Move the newly created application into the folder:
<startup Volume>:Users:<yourAccount>:Library:Scripts:Applications:Pages:
Maybe you would have to create the folder Pages and even the folder Applications by yourself.
select something in the source document
menu Scripts > Pages > exportTextBlocks
creates a new Pages document with the chunks of texts which where delimited by the markers.
--=====
The Finder's Help explains:
To make the Script menu appear:
Open the AppleScript utility located in Applications/AppleScript.
Select the "Show Script Menu in menu bar" checkbox.
--=====
Yvan KOENIG (Vallauris, FRANCE)
26 avril 2009
--=====
Here it would be easy to edit it if required
property marker : "______"
on run
my activateGUIscripting()
tell application "Pages" to tell document 1
set nDocSource to name
set source to body text
end tell -- Pages
set source to my decoupe(source, marker)
set extraits to {}
repeat with i from 1 to ((count of source) - 1) by 2
copy item (i + 1) of source to end of extraits
end repeat
copy "" to end of extraits
set extraits to my recolle(extraits, marker & return)
set destName to dateTimeStamp() & ".pages"
set destDoc to my makeNewPagesDoc(destName, path to documents folder as text)
tell application "Pages"
set body text of document destName to extraits (* inserts the extracted blocks *)
save document destName
my selectIworkDoc(name, nDocSource) (* back to source document *)
end tell -- Pages
end run
--=====
on decoupe(t, d)
local l
set AppleScript's text item delimiters to d
set l to text items of t
set AppleScript's text item delimiters to ""
return l
end decoupe
--=====
on recolle(l, d)
local t
set AppleScript's text item delimiters to d
set t to l as text
set AppleScript's text item delimiters to ""
return t
end recolle
--=====
on dateTimeStamp()
return (do shell script "date " & quote & "+P%Y%m%d-%H%M%S" & quote)
end dateTimeStamp
--=====
on makeNewPagesDoc(n, d)
local f, t
set f to d & n
set t to ((path to applications folder as text) & "iWork '09:Pages.app:Contents:Resources:Templates:Blank.template:") as alias
tell application "Pages"
open t
save document 1 as n in file f
end tell -- Pages
return d as alias
end makeNewPagesDoc
--=====
Use GUI scripting
on selectIworkDoc(a, n)
local m
if a = "Pages" then
set m to 9
else if a = "Numbers" then
set m to 10
else if a = "Keynote" then
set m to 11
else
error "The application “" & a & "“ is not accepted !"
end if
tell application a to activate
tell application "System Events" to tell application process a to tell menu bar 1 to tell menu bar item m to tell menu 1 to click menu item n
end selectIworkDoc
--=====
on activateGUIscripting()
tell application "System Events"
if not (UI elements enabled) then set (UI elements enabled) to true (* to be sure than GUI scripting will be active *)
end tell
end activateGUIscripting
--=====
--[/SCRIPT]
Yvan KOENIG (from FRANCE dimanche 26 avril 2009 22:32:24)