Multi batch renaming with automator

Question

Hi, everybody!
Hope I can find help in this section. Else, please forgive me if I posted in the wrong place...
I find myself in this situation.
I have many pdf's I need to transform into JPG's, but of course I need the name to be "meaningful". Each pdf contains 30 to 100 "sheets", that is to say it will produce from 30 to 100 jpgs
No problem with Automator and pdf-to-jpg.
Original pdf name: meaningless (something like "Scan_01")
JPG needed format: PREF_XXXXXX_EYY_S#
prefix is (by now) fixed: MAD
XXXXXX : a 6-digit progressive number BUT it has to increase each 4 jpg's
EYY: a progressive number that could be even set by hand, as it indicates the "Envelope" from which pdf's were scanned
S# : a number ranging from 1 to 4
Just to be clear (I hope), here is an example of how a correct output should look like:
MAD_123456_E01_S1
MAD_123456_E01_S2
MAD_123456_E01_S3
MAD_123456_E01_S4
MAD_123457_E01_S1
MAD_123457_E01_S2
MAD_123457_E01_S3
MAD_123457_E01_S4
MAD_123458_E01_S1
and so on.
Of course the point is not to prepend "MAD_" or whatever, and the "EYY" thing can go anywhere in the name (even after "MAD_"): I really don't know how to set a counter to switch from xxxxx1 to xxxxx2 each time S# reaches "S4" and, meanwhile, to reset "S#" to "S1".
Any advice on how to do that?

Answer 1

If I understand you correctly, you have a bunch of files that have been converted to jpg, and just want to rename them starting with a specified sequence.  The folowing Run AppleScript added to your workflow should be close - it extracts the name pieces from a dialog so that they can be manipulated and reassembled.  There isn't any error checking, it just assumes the format of the name is the same as the default answer:
property divider : "_" -- the character dividing the name pieces
on run {input, parameters}
     set output to {}
     set theAnswer to text returned of (display dialog "Enter starting sheet name:" default answer "MAD_123456_E01_S1")
     # break the name apart at divider - format is assumed to be the same as the default answer
     set {tempTID, AppleScript's text item delimiters} to {AppleScript's text item delimiters, divider}
     set {prefix, survey, envelope, page} to text items of theAnswer
     set AppleScript's text item delimiters to tempTID
     # extract numbers
     set envelope to text -2 thru -1 of envelope
     set page to (text -1 of page) - 1
     repeat with anItem in the input
          set page to page + 1
          if page > 4 then
               set page to 1
               set survey to survey + 1
          end if
          set theEnvelope to "E" & text -2 thru -1 of ("00" & envelope) -- leading zero
          set thePage to "S" & page
          tell application "Finder"
               set name of anItem to prefix & divider & survey & divider & theEnvelope & divider & thePage & ".jpg"
               set end of output to anItem as alias
          end tell
     end repeat
     return output
end run
Edit: I am a he, by the way.