Native Web Services and Collection of Records

Question

Hi
I want to use XMLDB Native Web Services but one of my requirements is for the web service to pass in to Oracle a collection of records as a input parameter to the stored procedure.
What is the best way to achieve this with Native Web Services ? A couple of options I can think of below, are there any others ?
1. Create a stored procedure with an IN parameter defined as CLOB or XMLTYPE (which is best, does DBNWS work with XMLTYPE ?) and structure the XSD/XML to contain the required record structure. See below
CREATE OR REPLACE PROCEDURE test_using_xml (
p_xmlin IN XMLTYPE,
p_xmlout OUT XMLTYPE) AS
BEGIN
BLAH, BLAH, BLAH;
END;
2. Define TYPES as below
CREATE OR REPLACE TYPE MEMBER_REC AS OBJECT
(FIRST_NAME VARCHAR2(10),
LAST_NAME VARCHAR2(10));
CREATE OR REPLACE TYPE MEMBER_TAB AS TABLE OF MEMBER_REC;
CREATE OR REPLACE TYPE MEMBER_TAB_OBJ AS OBJECT (DUMMY MEMBER_TAB);
CREATE OR REPLACE PROCEDURE get_quote (
p_members IN MEMBER_TAB_OBJ) AS
BEGIN
NULL;
END;
Thanks

Answer 1

This is what we ended up using, creating complex object types. Seems to work quite well. The object also is effective your SOA Contract which is quite nice.
The generated WSDL is reasonably straight forward and logical apart from a few naming quirks.
CREATE OR REPLACE TYPE MEMBER_REC_IN AS OBJECT
(PERSON_NUMBER CHAR(2),
RELATIONSHIP_CODE CHAR(1),
FIRST_NAME VARCHAR2(10),
LAST_NAME VARCHAR2(10),
GENDER CHAR(1),
DATE_OF_BIRTH DATE);
CREATE OR REPLACE TYPE MEMBER_REC_OUT AS OBJECT
(PERSON_NUMBER CHAR(2),
API NUMBER);
CREATE OR REPLACE TYPE MEMBER_TAB_IN AS TABLE OF MEMBER_REC_IN;
CREATE OR REPLACE TYPE MEMBER_TAB_OUT AS TABLE OF MEMBER_REC_OUT;
CREATE OR REPLACE TYPE GET_QUOTE_SUBMIT_OBJ AS OBJECT (MESSAGE_GUID VARCHAR2(2000),
EFFECTIVE_DATE DATE,
PRODUCT_CODE VARCHAR2(12),
GROUP_ID VARCHAR2(12),
ADDRESS_LINE1 VARCHAR2(50),
ADDRESS_LINE2 VARCHAR2(50),
CITY VARCHAR2(50),
COUNTRY VARCHAR2(50),
POSTCODE VARCHAR2(10),
FAMILY MEMBER_TAB_IN);
CREATE OR REPLACE TYPE GET_QUOTE_RESPONSE_OBJ AS OBJECT (MESSAGE_GUID VARCHAR2(2000),
QUOTE_NUMBER NUMBER,
API NUMBER,
FAMILY MEMBER_TAB_OUT,
RESULT_CODE NUMBER,
RESULT_DESCRIPTION VARCHAR2(2000));
CREATE OR REPLACE PROCEDURE get_quote (
p_quote_in IN GET_QUOTE_SUBMIT_OBJ,
p_quote_out OUT GET_QUOTE_RESPONSE_OBJ) AS
BEGIN
-- Initiliase the record
p_quote_out := GET_QUOTE_RESPONSE_OBJ(NULL,NULL,NULL,MEMBER_TAB_OUT(),NULL,NULL);
p_quote_out.message_guid := p_quote_in.message_guid;
p_quote_out.quote_number := 123456;
p_quote_out.api := 999.99;
-- Loop thru the members passed in
FOR idx IN 1..p_quote_in.family.count LOOP
-- Extend the array
p_quote_out.family.EXTEND(1);
-- Initiliase the record
p_quote_out.family(idx) := MEMBER_REC_OUT(NULL,NULL);
p_quote_out.family(idx).person_number := p_quote_in.family(idx).person_number;
p_quote_out.family(idx).api := idx * 100;
END LOOP;
p_quote_out.result_code := 0;
p_quote_out.result_description := 'test';
END;
/