NEED A FUNCTION WHICH CAN DECODE THE URL

Question

Hi all,
I am trying to decode the URL which appears in the address link.
Please read the following for more clarification:
On some search engine, I type the search item.
Say Google is the search engine
The search criteria that i gave is
Case 1
"Human Resources"
Resulting URL
"http://www.google.com/search?biw=1003&hl=en&q=Human+Resources"
Expected result after decoding the URL is
Human Resource
Case 2
Seaechitem http:// oracle
Result
http://www.google.com/search?hl=en&lr=&biw=1003&q=http%3A+%2F%2F+oracle
Expected Result after decoding the URL:
http:// oracle
Can anybody suggest me how to achieve this goal using Oracle?
Is there any function/procedure or any utility available to do it?
Thanks in advance.
Himanshu

Answer 1

Hi,
You lucky guy... I did something really close to what you need. I modified the code a bit (there might be some glitches) to match your requirements:DECLARE
     ref1 VARCHAR2(1000 CHAR) := 'http://www.google.fr/search?hl=fr\&biw=1280\&q=http%3A+%2F%2F+oracle\&btnG=Rechercher\&meta=';
     ref2 VARCHAR2(1000 CHAR) := 'http://www.google.fr/search?hl=fr\&biw=1280\&q=Human+Resources\&btnG=Rechercher\&meta=';
     FUNCTION hextodec( h IN VARCHAR ) RETURN NUMBER
     AS
          h2 VARCHAR2( 10 );
          i NUMBER( 10 );
          j NUMBER( 2 );
          d NUMBER;
     BEGIN
          h2 := LTRIM( h, '0' );
          d := 0;
          FOR i IN 1 .. LENGTH( h2 )
          LOOP
               SELECT DECODE( SUBSTR( h2, i, 1 )
                    , '0', 0, '1', 1, '2', 2, '3', 3, '4', 4, '5', 5
                    , '6', 6, '7', 7, '8', 8, '9', 9, 'A', 10
                    , 'B', 11, 'C', 12, 'D', 13, 'E', 14, 'F', 15 )
                    INTO j
                    FROM DUAL;
               d := 16 * d + j;
          END LOOP;
          RETURN d;
     END hextodec;
     FUNCTION strip(samplevalue IN VARCHAR2) RETURN VARCHAR2
     AS
          finalvalue VARCHAR2(1000 CHAR) := samplevalue;
          decimalvalue NUMBER(2);
          pospct NUMBER;
          extract VARCHAR2(2 CHAR);
     BEGIN
          finalvalue := SUBSTR(finalvalue ,INSTR(finalvalue ,'\&q='));
          finalvalue := SUBSTR(finalvalue ,4);
          finalvalue := SUBSTR(finalvalue ,1,INSTR(finalvalue ,'\&')-1);
          finalvalue := REPLACE(finalvalue ,'+',' ');
          LOOP
               pospct := INSTR(finalvalue ,'%');
               EXIT WHEN pospct = 0;
               extract := SUBSTR(finalvalue ,pospct+1,2);
               finalvalue  := SUBSTR(finalvalue ,1,pospct-1) || chr(hextodec(extract)) || SUBSTR(finalvalue ,pospct+3);
          END LOOP;
          RETURN finalvalue;
     END;
BEGIN
     DBMS_OUTPUT.PUT_LINE(strip(ref1));
     DBMS_OUTPUT.PUT_LINE(strip(ref2));
END;
/Warning: ESCAPE must be ON in order to do that under SQL*Plus (because of the '&').
Regards,
Yoann.