Need help in XSLT

Question

Hi all, I am working on xslt for the xml document which is similar to this :-
<?xml version="1.0" encoding="UTF-8"?>
     <soapenv:Envelope      xmlns:soapenv="peopledirectory">
     *<soapenv:Header/>*
     <soap-env:Body      xmlns:soap-env="propleaccess">
     <medi:MEDI_DEV_OSB_POCOutputCollection      xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance"
xmlns:medi="http://xmlns.oracle.com/pcbpel/adapter/db/MEDI_DEV_OSB_POC">
<medi:MEDI_DEV_OSB_POCOutput>
     <medi:STUDYID>123</medi:STUDYID>
     <medi:DOMAIN>CTS</medi:DOMAIN>
</medi:MEDI_DEV_OSB_POCOutput>
<medi:MEDI_DEV_OSB_POCOutput>
     <medi:STUDYID>123</medi:STUDYID>
     <medi:DOMAIN>CTS</medi:DOMAIN>
</medi:MEDI_DEV_OSB_POCOutput>
     </medi:MEDI_DEV_OSB_POCOutputCollection>
     </soap-env:Body>
     </soapenv:Envelope>
In the above xml if you observe the part in Bold it is an element which is closed inside the envelope with no matter in it.. I wonder how to go beyond this <Header/> element using
xpath so as to select it in the template tag. I need the result xml should be somethiing like the below :-
<?xml version="1.0" encoding="UTF-8"?>
     <soapenv:Envelope      xmlns:soapenv="peopledirectory">
     <soapenv:Header/>
     <soap-env:Body      xmlns:soap-env="propleaccess">
     <medi:MEDI_DEV_OSB_POCOutputCollection      xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance"
xmlns:medi="http://xmlns.oracle.com/pcbpel/adapter/db/MEDI_DEV_OSB_POC">
<medi:MEDI_DEV_OSB_POCOutput>
<NewElement1 name = STUDENTID value = 123/>
<NewElement2 name = DOMAIN value = CTS/>
</medi:MEDI_DEV_OSB_POCOutput>
Something like this...
To achieve this I wrote the below xslt
<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:soapenv="peopledirectory" xmlns:soap-env="propleaccess          xmlns:medi="http://xmlns.oracle.com/pcbpel/adapter/db/MEDI_DEV_OSB_POC">
<xsl:output method = "xml" intend = "yes"/>
<xsl:template match = "soapenv:Envelope/soapenv:Header"></xsl:template>
<xsl:template match = "soapenv:Envelope/soap-env:Body/medi:MEDI_DEV_OSB_POCOutputCollection/medi:MEDI_DEV_OSB_POCOutput" >
     <xsl:for-each select="medi:MEDI_DEV_OSB_POCOutput/medi:STUDYID">
     <xsl:element name="Name">
     <xsl:value-of select="medi:STUDYID"></xsl:value-of>
     </xsl:element>
     </xsl:for-each>
     </xsl:template>
</xsl:stylesheet>
Using this xslt I am not getting the result xml as how I needed. I am getting just the text values of nodes in my result xml. Kindly help me on this.
Thanks,
Phanindra.

Answer 1

If by NewElement1, NewElement2... you mean NewElement literally (replaced by whatever real name you choose) whereas 1,2,... have no generic meaning, you can do this.
<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:soapenv="peopledirectory"
    xmlns:soap-env="propleaccess"
    xmlns:medi="http://xmlns.oracle.com/pcbpel/adapter/db/MEDI_DEV_OSB_POC">
<xsl:output method = "xml" indent="yes"/>
<xsl:strip-space elements="*" />
<xsl:template match="*|@*|text()|processing-instruction()|comment()">
    <xsl:copy>
        <xsl:apply-templates select="*|@*|text()|processing-instruction()|comment()" />
    </xsl:copy>
</xsl:template>
<xsl:template match = "medi:MEDI_DEV_OSB_POCOutput" >
    <xsl:copy>
        <xsl:for-each select="*">
            <NewElement name="{local-name()}" value="{normalize-space()}" />
        </xsl:for-each>
    </xsl:copy>
</xsl:template>
</xsl:stylesheet>If you attach generic meaning to 1,2,... you can replace the corresponding template by this.
<xsl:template match = "medi:MEDI_DEV_OSB_POCOutput" >
    <xsl:copy>
        <xsl:for-each select="*">
            <xsl:element name="{concat('NewElement',position())}">
                <xsl:attribute name="name">
                    <xsl:value-of select="local-name()" />
                </xsl:attribute>
                <xsl:attribute name="value">
                    <xsl:value-of select="normalize-space()" />
                </xsl:attribute>
            </xsl:element>
        </xsl:for-each>
    </xsl:copy>
</xsl:template>I go for these details just because some technique used might help you one-day in other contexts.
Edited by: tsuji on Feb 15, 2012 2:26 AM Essential correction made to the 2nd template.