Obtain string of IN variable name in PL/SQL

Question

Hi,
Odd question. Is there a way to access an IN variable's object name in a procedure?
eg.
procedure (var1    IN VARCHAR2(6),
                var2    IN VARCHAR2(6),
                var3    IN VARCHAR2(6))
IS....You run this procedure and pass in parameters of:
var1 => 'abcdef',
var2 => 'defghi',
var3 => 'ghikjl';
In the code, I want to access the number in the string of the +variable name: var1+
In a naive sense,
num_of_in_var := substr(var1, 4,1) would be what i was hoping to achieve, but,
var1 is set to 'abcdef' so,
num_of_in_var := substr(var1, 4,1) would return 'd'.
Any thoughts?
Thanks
Edited by: chris001 on Nov 20, 2012 1:16 PM

Answer 1

Here's an example of how (what you want to do using a procedure or function), can be done using a ADT/UDT (Advance/User Defined Type) in Oracle.
This approach will not work for standard procedures and functions as this type of dynamic referencing of the code unit/object to itself, is not possible.
SQL> create or replace type TSomeObject as object(
  2          name    varchar2(10),
  3          id      integer,
  4          day     date,
  5 
  6          member function PropertyByNumber( n integer ) return varchar2
  7  );
  8  /
Type created.
SQL>
SQL> create or replace type body TSomeObject as
  2 
  3          member function PropertyByNumber( n integer ) return varchar2 is
  4                  PLSQL_PROP_GET  constant varchar2(1000) :=
  5                          'declare
  6                                  obj     TSomeObject;
  7                          begin
  8                                  obj := :1;
  9                                  :2 := to_char( obj.#PROPERTY# );
10                          end;';
11 
12                  type            TStrings is table of varchar2(30);
13                  property        TStrings;
14                  dynamicBlock    varchar2(1000);
15                  res             varchar2(4000);
16          begin
17                  select
18                          a.attr_name bulk collect into property
19                  from    user_type_attrs a
20                  where   a.type_name = 'TSOMEOBJECT'
21                  order by
22                          a.attr_no;
23 
24                  dynamicBlock := replace( PLSQL_PROP_GET, '#PROPERTY#', property(n) );
25                  execute immediate dynamicBlock
26                  using   in self,
27                          out res;
28 
29                  return( res );
30          end;
31 
32  end;
33  /
Type body created.
SQL>
SQL> declare
  2          obj     TSomeObject;
  3  begin
  4          obj := new TSomeObject( 'John Doe', 123, trunc(sysdate) );
  5 
  6          for i in 1..3 loop
  7                  dbms_output.put_line( 'property '||i||'='||obj.PropertyByNumber(i) );
  8          end loop;
  9  end;
10  /
property 1=John Doe
property 2=123
property 3=2012/11/23 00:00:00
PL/SQL procedure successfully completed.
SQL> Simplistic example (the PropertyByNumber could be a static class method defined in the abstract parent class) - and one that requires the object to essentially duplicate itself via a bind variable call to dynamic code. Not really the best of approaches, but demonstrates the flexibility (to do even interestingly weird stuff) in PL/SQL.