OLE2 Manipulation of embedded Excel object - need assistance

Question

We are struggling to successfully manipulate an OLE2 embedded Excel spreadsheet from within Forms to update the cells driving an Excel chart using data from an Oracle data table.
All code examples we have found deal with opening an existing file based Excel spreadsheet using OLE2 and manipulating that object, but we have found nothing on opening an embedded Excel spreadhsheet object.
Using the GET_INTERFACE_POINTER function passing in the name of the OLE2 item to obtain a handle to the spreadsheet embedded object seems to return a valid value, but referencing this handle in subsequent calls to GET_OBJ_PROPERTY fails.
The documentation suggests that calling the GET_INTERFACE_POINTER function passing in the name of the OLE2 container item that contains the embedded spreadsheet should open the spreadsheet, activate the spreadsheet and return a handle to the spreadsheet. The behavior doesn't suggest this causing us to wonder if the docs are not accurate and we are really getting back a handle only to the OLE2 container and not to the spreadsheet itself. If this theory is true then how does one properly reference the spreadsheet?
Can anyone shed some light preferably in the form of some working code examples of how we can manipulate Excel 'Cell' objects in a Forms OLE2 embedded Excel spreadsheet?
Any assistance is greatly appreciated!
[email protected]

Answer 1

Try to use:
DECLARE
  handle ole2.obj_type;
  MySheet ole2.obj_type;
  appHandle ole2.obj_type;
  ok_verb boolean;
  MyRange ole2.obj_type;
  args ole2.list_type;
  ret_val varchar2(32000);
  row pls_integer:=1;
  col pls_integer:=1;
  new_val varchar2(1000);
  verb_cnt_str varchar2(100);
  verb_cnt pls_integer;
  loop_cntr pls_integer;
  verb_name varchar2(1000);
BEGIN
  select TO_CHAR( sysdate, 'dd.mm.yyyy hh.mi.ss' ) INTO new_val FROM dual;
  -- Open document
  ok_verb:=false;
  verb_cnt_str := Forms_OLE.Get_Verb_Count('OLE1');
  verb_cnt := TO_NUMBER(verb_cnt_str); 
  FOR loop_cntr in 1..verb_cnt
  LOOP   
    verb_name := Forms_OLE.Get_Verb_Name('OLE1',loop_cntr);
    IF   verb_name = 'Open'   -- In English language
         OR verb_name='Nrjp{r|'  -- In Russian language (CP1251)
         THEN
           EXEC_VERB('OLE1',verb_name);
           ok_verb:=true;
    END IF;
  END LOOP;
  -- Check the errors
  IF NOT ok_verb THEN
       Message( 'Can''t found correct VERB');
       return;
  END IF;
  -- Get handle of item. (Who is it ? I don't know. :) )
  handle := forms_ole.get_interface_pointer('OLE1');
  -- Get handle of Excel application
  appHandle := ole2.Get_Obj_Property( handle, 'Application' );
-- If you want, You can hide the Excel application
-- ole2.set_Property( appHandle, 'Visible', 0 );
  -- Get ActiveSheet
  MySheet:=ole2.Get_Obj_Property( handle, 'ActiveSheet' );
  -- Cells(row,col)
  args:=OLE2.CREATE_ARGLIST;
  OLE2.ADD_ARG(args,row);
  OLE2.ADD_ARG(args,col);
  MyRange:= OLE2.GET_OBJ_PROPERTY( MySheet,'Cells',args);
  OLE2.INVOKE (MyRange,'Activate');
  OLE2.DESTROY_ARGLIST(args);
  -- Get the Cell value
  ret_val:=OLE2.GET_CHAR_PROPERTY( MyRange,'Value' );
  -- And modify it (to current date)
  OLE2.SET_PROPERTY( MyRange,'Value', new_val );
  -- Release handle 
  OLE2.RELEASE_OBJ( MyRange );
  OLE2.RELEASE_OBJ( MySheet );
  -- Save document
  -- 1. Set DisplayAlerts property of Excel Application object
  -- to FALSE ( 0=false, 1=true )
  ole2.SET_PROPERTY( appHandle, 'DisplayAlerts', 0 );
  ole2.invoke( appHandle, 'Save' );
  -- Close the Application
  ole2.invoke( appHandle, 'Quit' );
  -- Release handle
  ole2.release_obj( appHandle );
  ole2.release_obj( handle );
  Message( 'prev. value in Cells(1,1)='||ret_val);
  Message( ' ', NO_ACKNOWLEDGE );
END;