ORA-00936: Missing Expression? please help

Question

i just created the following function. I am passing the parameter, which is a varchar2 datatype. The result i am trying to get from this function is also a varchar2, which makes sense since the table is a table that only has varchar2 datatypes. . .so i guess i need to convert the result to a number. How do i do this? I don't quite know the syntax.
when i try and run what i have i get the following error:
ORA-00936: missing expression
ORA-06512: at "SMSRPT.GET_NUMBER", line 8
ORA-06512: at line 7
create or replace FUNCTION get_number(p_name VARCHAR2) return NUMBER as
--DECLARE
v_value varchar2(100);
v_result varchar2(100);
     BEGIN
          v_value:='select value from config_params where name='||p_name;
          execute immediate v_value into v_result;
return v_result;
END;

Answer 1

How about this (updating polasa's response)
CREATE OR REPLACE FUNCTION new_number(p_name VARCHAR2) RETURN NUMBER AS
v_value VARCHAR2(1000);
v_result NUMBER;
BEGIN
v_value :=('select value from config_param where name = :1');
EXECUTE IMMEDIATE v_value
INTO v_result USING p_name;
RETURN v_result;
END new_number;or this
CREATE OR REPLACE FUNCTION get_number(p_name VARCHAR2) RETURN NUMBER AS
   v_value VARCHAR2(1000);
   v_result NUMBER;
   TYPE rct_cursor IS REF CURSOR; --REF CURSOR for dynamic Cursors.
   d_sql        rct_cursor;
BEGIN
  v_value := 'select value from config_param where name = :1';
  OPEN d_sql
  FOR v_value
    USING p_name;
  FETCH d_sql INTO v_result;
  IF d_sql%NOTFOUND THEN
     v_result := NULL;
  END IF;
  CLOSE d_sql;
  RETURN v_result;
END get_number; so the answer is "yes it can be done in dynamic SQL". The question is why do you want to given the advantages of static SQL over dynamic SQL?