Oracle user defined errors

Question

hi friends i defined lots of errors code in my plssql proc,func...
like
RAISE_APPLICATION_ERROR(-20322,'invalid username');but now application lots of error message and its looks to mixed. how can i define and manage errors?
thanks

Answer 1

ok, here's a very quick and rough example...
SQL> create or replace package pkg_err_handle is
  2    err_no_salary     exception; pragma exception_init(err_no_salary, -20001);
  3    err_no_department exception; pragma exception_init(err_no_department, -20002);
  4    err_invalid_bonus exception; pragma exception_init(err_invalid_bonus, -20003);
  5    --
  6    procedure raise_err(err_name in varchar2);
  7    --
  8    procedure log_err;
  9  end;
10  /
Package created.
SQL>
SQL> create or replace package body pkg_err_handle is
  2    procedure raise_err(err_name in varchar2) is
  3    begin
  4      case lower(err_name)
  5        when 'err_no_salary' then log_err; raise_application_error(-20001, 'Salary Must Be Entered', true);
  6        when 'err_no_deparment' then log_err; raise_application_error(-20002, 'Deparment Must Be Entered', true);
  7        when 'err_invalid_bonus' then log_err; raise_application_error(-20003, 'Bonus cannot be more than Salary', true);
  8      else log_err; raise_application_error(-20000, 'Undefined Error', true);
  9      end case;
10    end;
11    --
12    procedure log_err is
13    begin
14      -- here you would probably log to a table (preferably) or file.
15      dbms_output.enable(1000000);
16      dbms_output.put_line('Error Log: '||DBMS_UTILITY.FORMAT_ERROR_BACKTRACE());
17    end;
18  end;
19  /
Package body created.
SQL> declare
  2    v_empno number := 7654;
  3    v_sal   number;
  4    v_bonus number;
  5  begin
  6    select sal, comm
  7    into v_sal, v_bonus
  8    from emp
  9    where empno = v_empno;
10    --
11    if v_bonus > v_sal then
12      pkg_err_handle.raise_err('err_invalid_bonus');
13    end if;
14    --
15    -- all is ok
16    --
17  exception
18    when pkg_err_handle.err_invalid_bonus then
19      -- handle or raise...
20      raise;
21  end;
22  /
Error Log:
declare
ERROR at line 1:
ORA-20003: Bonus cannot be more than Salary
ORA-06512: at line 20
SQL>You'd probably want to include more information in the raising of the error, perhaps including some internal reference that could be logged to indicate the place in the code the error was raised from etc.