Pass a set of Records form Form to a Report

Question

Hi,
Lets say that I've already fetched a set of records on Oracle Form, and I want to pass these reocrds to a Report " on the Report I dont wana use range or where clause to give me these recods"
Any ideas how to do that please?
Thanks!

Answer 1

Passing a (Forms) Record Group as DATA_PARAMETER to Reports:
First example:
Forms code (in WHEN-BUTTON-PRESSED trigger) calls reports module
and sends record group "rg_dept" (populated from :SYSTEM.LAST_QUERY) as parameter:
DECLARE
rg_id_l RECORDGROUP;
rg_name_l VARCHAR2 (30) := 'RG_DEPT';
status_l NUMBER;
pl_id_l PARAMLIST;
pl_name_l VARCHAR2 (30) := 'PARAM_LIST';
BEGIN
rg_id_l := FIND_GROUP (rg_name_l);
IF NOT ID_NULL (rg_id_l) THEN
DELETE_GROUP (rg_id_l);
END IF;
rg_id_l := CREATE_GROUP_FROM_QUERY (rg_name_l, :SYSTEM.LAST_QUERY);
status_l := POPULATE_GROUP (rg_id_l);
IF status_l <> 0 THEN
RAISE FORM_TRIGGER_FAILURE;
END IF;
pl_id_l := GET_PARAMETER_LIST (pl_name_l);
IF NOT ID_NULL (pl_id_l) THEN
DESTROY_PARAMETER_LIST (pl_id_l);
END IF;
pl_id_l := CREATE_PARAMETER_LIST (pl_name_l);
ADD_PARAMETER (pl_id_l, 'Q_1', DATA_PARAMETER, rg_name_l);
RUN_PRODUCT (REPORTS, 'rec_group', SYNCHRONOUS, RUNTIME, FILESYSTEM, pl_id_l, NULL);
END;
Reports module must have query with the same name as parameter in ADD_PARAMETER
statement (in this code - "Q_1"), and SQL Query Statement in Reports must have
same number and type of columns as record group, for example:
SELECT ROWID, 1 deptno, 'x' dname, 'x' loc FROM DUAL
And - we can't pass a DATA_PARAMETER to a child query in Report Builder.
Data passing is supported only for master queries.
Second example:
Forms transfers to Reports records from "dept" block,
using non-query record group (populated from Forms "dept" block in a LOOP):
DECLARE
rg_id_l RECORDGROUP;
rg_name_l VARCHAR2 (30) := 'DEPT';
row_count_l NUMBER;
rgc_id_l GROUPCOLUMN;
pl_id_l PARAMLIST;
pl_name_l VARCHAR2 (30) := 'PARAM_LIST';
BEGIN
rg_id_l := FIND_GROUP (rg_name_l);
IF NOT ID_NULL (rg_id_l) THEN
DELETE_GROUP (rg_id_l);
END IF;
rg_id_l := CREATE_GROUP (rg_name_l);
rgc_id_l := ADD_GROUP_COLUMN (rg_id_l, 'deptno', NUMBER_COLUMN);
rgc_id_l := ADD_GROUP_COLUMN (rg_id_l, 'dname', CHAR_COLUMN, 14);
rgc_id_l := ADD_GROUP_COLUMN (rg_id_l, 'loc', CHAR_COLUMN, 13);
GO_BLOCK ('dept');
FIRST_RECORD;
row_count_l := 0;
LOOP
row_count_l := row_count_l + 1;
ADD_GROUP_ROW (rg_id_l, row_count_l);
SET_GROUP_NUMBER_CELL (rg_name_l || '.deptno', row_count_l, :dept.deptno);
SET_GROUP_CHAR_CELL (rg_name_l || '.dname', row_count_l, :dept.dname);
SET_GROUP_CHAR_CELL (rg_name_l || '.loc', row_count_l, :dept.loc);
EXIT WHEN :SYSTEM.LAST_RECORD = 'TRUE';
NEXT_RECORD;
END LOOP;
IF row_count_l = 0 THEN
MESSAGE ('Nothing to print'); PAUSE;
RETURN;
END IF;
pl_id_l := GET_PARAMETER_LIST (pl_name_l);
IF NOT ID_NULL (pl_id_l) THEN
DESTROY_PARAMETER_LIST (pl_id_l);
END IF;
pl_id_l := CREATE_PARAMETER_LIST (pl_name_l);
ADD_PARAMETER (pl_id_l, 'Q_1', DATA_PARAMETER, rg_name_l);
RUN_PRODUCT (REPORTS, 'REC_GROUP_REPORT', SYNCHRONOUS, RUNTIME, FILESYSTEM, pl_id_l, NULL);
END;
This works in Forms 6i. In Forms 9i we must use RUN_REPORT_OBJECT instead of RUN_PRODUCT
(see Oracle MetaLink document 110495.1 "Passing a Record Group to Reports Using RUN_REPORT_OBJECT").
Regards,
Zlatko Sirotic