Passing an array as IN parameter to call a function

Question

I have a function the definition is
TYPE VAR_VALUE_RECORD IS RECORD(VAR VARCHAR2(100),
               VALUE VARCHAR2(100));
TYPE VAR_VALUE_TAB IS TABLE OF VAR_VALUE_RECORD;
FUNCTION GENERIC_WF(P_MSG_TYPE IN VARCHAR2,P_CDCS_NBR IN VARCHAR2, P_CDCS_SEQ IN VARCHAR2, P_DEBTORID IN NUMBER,
P_EXTRAS IN VAR_VALUE_TAB) RETURN VARCHAR2;
I am trying to call this function
select WF_NOTIFICATIONS_PKG.GENERIC_WF('Manual Debt Establish Notification','2009A13636','001',105195359,'this is a test') from dual
ERROR at line 1:
ORA-06553: PLS-306: wrong number or types of arguments in call to 'GENERIC_WF'
I am getting the above error, how do I pass the array as parameter.
I will appreciate your help.
Thnaks

Answer 1

Hi,
try this,
Create OR Replace Package WF_NOTIFICATIONS_PKG Is
   Type VAR_VALUE_RECORD Is Record( VAR   Varchar2(100)
                                  , Value Varchar2(100));
   Type VAR_VALUE_TAB Is Table Of VAR_VALUE_RECORD Index BY Pls_Integer;
   Function GENERIC_WF( P_MSG_TYPE IN Varchar2
                      , P_CDCS_NBR IN Varchar2
                      , P_CDCS_SEQ IN Varchar2
                      , P_DEBTORID IN Number
                      , P_EXTRAS   IN VAR_VALUE_TAB ) Return Varchar2;
End WF_NOTIFICATIONS_PKG;
Create OR Replace Package Body WF_NOTIFICATIONS_PKG Is
   Function GENERIC_WF( P_MSG_TYPE IN Varchar2
                      , P_CDCS_NBR IN Varchar2
                      , P_CDCS_SEQ IN Varchar2
                      , P_DEBTORID IN Number
                      , P_EXTRAS   IN VAR_VALUE_TAB ) Return Varchar2 Is
   Begin
      Return ( P_EXTRAS(P_EXTRAS.First).var || ' - ' || P_EXTRAS(P_EXTRAS.First).Value );
   End GENERIC_WF;
End WF_NOTIFICATIONS_PKG;
SQL> Declare
  2     v_value_Tab WF_NOTIFICATIONS_PKG.VAR_VALUE_TAB;
  3     v_return    Varchar2(100);
  4  Begin
  5     v_value_Tab(1).var   := 'this is a test 1';
  6     v_value_Tab(1).value := 'this is a test 2';
  7 
  8     v_return := WF_NOTIFICATIONS_PKG.GENERIC_WF( 'Manual Debt Establish Notification'
  9                                                , '2009A13636'
10                                                , '001'
11                                                , 105195359
12                                                , v_value_Tab );
13 
14     Dbms_Output.put_line(v_return);
15  End;
16  /
this is a test 1 - this is a test 2
PL/SQL procedure successfully completedRegards,
Christian Balz